options:
    prefix: &8[&eSerwer&8] # przedrostek wiadomości
    adminChatSymbol: "!" # symbol, który musi być przed wiadomością, żeby była wysłana na admin chat (może być dłuższy, np. "ac!")
    
    # Wiadomości
    noPermissionMessage: &cNie masz uprawnień aby tego użyć!
    noTextMessage: &cMusisz coś wpisać!
    
    #Uprawnienia
    acCommandPermission: "adminchat.command" # Uprawnienie do komendy /adminchat
    acByChatPermission: "adminchat.bychat" # Uprawnienie do pisania na admin chacie poprzez chat
    seeingAcPermission: "adminchat.see" # Uprawnienie do widzenia admin chatu
    
    # Format
    acPrefix: &8[&cAdminChat&8] # Prefix w admin chacie
    acPlayerNameColor: &a # Kolor nazwy gracza w admin chacie
    acMessageColor: &b # Kolor wiadomości w admin chacie
    acArrowColor: &8 # Kolor strzałki w admin chacie

command /adminchat [<text>]:
    aliases: ac
    permission: adminchat.command
    permission message: {@prefix} {@noPermissionMessage}
    trigger:
        if arg 1 is not set:
            send "{@prefix} {@noTextMessage}"
            stop
        adminChat(arg-1, executor)
        
on chat:
    (length of {@adminChatSymbol}) first characters of message = {@adminChatSymbol}
    player has permission {@acByChatPermission}
    cancel event
    length of uncolored message > (length of {@adminChatSymbol})
    set {_length} to (length of {@adminChatSymbol}) + 1
    adminChat(subtext of uncolored message from characters {_length} to (length of uncolored message), player)
        
function adminChat(msg: string, p: executor):
    set {_formattedMsg} to "{@acPrefix} {@acPlayerNameColor}%{_p}% {@acArrowColor}» {@acMessageColor}%{_msg}%"
    send {_formattedMsg} to all players where [input has permission {@seeingAcPermission}] and console