function parseTime(time: number) :: text:
    set {_days} to rounded down ({_time} / 86400)
    set {_hours} to rounded down (mod({_time}, 86400) / 3600)
    set {_mins} to rounded down (mod({_time}, 3600) / 60)
    set {_secs} to rounded down mod({_time}, 60)
    set {_time} to ""
    if {_days} > 0:
        set {_time} to "%{_days}%d %{_hours}%h %{_mins}%min %{_secs}%sek"
    else if {_hours} > 0:
        set {_time} to "%{_hours}%h %{_mins}%min %{_secs}%sek"
    else if {_mins} > 0:
        set {_time} to "%{_mins}%min %{_secs}%sek"
    else:
        set {_time} to "%{_secs}%sek"
    return {_time}
    
on join:
    if {playtime::%player%} is not set:
        set {playtime::%player%} to 0
    set {sesja::%player%} to unix timestamp of now
    
on quit:
    set {_now} to unix timestamp of now
    set {playtime::%player%} to {playtime::%player%} + ({_now} - {sesja::%player%})
    
command /czas [<offlineplayer>]:
    trigger:
        if arg 1 is not set:
            set {_now} to unix timestamp of now
            set {_time} to {playtime::%player%} + ({_now} - {sesja::%player%})
            send "&3Twoj czas gry: &7%parseTime({_time})%"
            stop
        if arg 1 is online:
            set {_now} to unix timestamp of now
            set {_time} to {playtime::%arg 1%} + ({_now} - {sesja::%arg 1%})
        else:
            set {_time} to {playtime::%arg 1%}
        send "&3Czas gry %arg 1%: &7%parseTime({_time})%"
        
command /czasr [<text>]:
    permission: *
    permission message: &cBrak permisji!
    trigger:
        if arg 1 is not set:
            send "&cUzycie: &7/czasr <gracz|all>"
            stop
        if arg 1 is "all":
            loop {playtime::*}:
                set {playtime::%loop-index%} to 0
            loop {sesja::*}:
                if (loop-index parsed as offlineplayer) is online:
                    set {sesja::%loop-index%} to unix timestamp of now
                else:
                    clear {sesja::%loop-index%}
            send "&aPomyslnie wyczyszczono czas gry wszystkich graczy"
            stop
        set {_player} to arg 1 parsed as offlineplayer
        set {playtime::%{_player}%} to 0
        if {_player} is online:
            set {sesja::%{_player}%} to unix timestamp of now
        else:
            clear {sesja::%{_player}%}
        send "&aPomyslnie wyczyszczono czas gry %arg 1%"