# ███╗░░░███╗░█████╗░██████╗░███╗░░░███╗░█████╗░███╗░░██╗░█████╗░░██████╗░███████╗██████╗░
# ████╗░████║██╔══██╗██╔══██╗████╗░████║██╔══██╗████╗░██║██╔══██╗██╔════╝░██╔════╝██╔══██╗
# ██╔████╔██║██║░░██║██████╦╝██╔████╔██║███████║██╔██╗██║███████║██║░░██╗░█████╗░░██████╔╝
# ██║╚██╔╝██║██║░░██║██╔══██╗██║╚██╔╝██║██╔══██║██║╚████║██╔══██║██║░░╚██╗██╔══╝░░██╔══██╗
# ██║░╚═╝░██║╚█████╔╝██████╦╝██║░╚═╝░██║██║░░██║██║░╚███║██║░░██║╚██████╔╝███████╗██║░░██║
# ╚═╝░░░░░╚═╝░╚════╝░╚═════╝░╚═╝░░░░░╚═╝╚═╝░░╚═╝╚═╝░░╚══╝╚═╝░░╚═╝░╚═════╝░╚══════╝╚═╝░░╚═╝

# Witaj w MobManager!
# Chcesz zarządzać mobami i robić walki między nimi, ale wkurza Cię instalowanie modów i długie komendy?
# Nie? No dobra :(
# Ale jeśli kiedyś będziesz chciał, to pozostawiam Ci ten skrypt!
# Jeśli jesteś zainteresowany, to pozwól że wytłumaczę Ci jak działa.
# 1. Co dodaje MobManager?
# Ten skrypt dodaje 4 nowe (domyślnie patyki) zarządzające:
# Atakiem na wybranego moba przez innego wybranego moba,
# równą walką między nimi,
# zarządzaniem ekwipunkiem wybranego moba,
# oraz możliwość skopiowania i wklejenia mobów.
# Dodana została jeszcze komenda /magic <id przedmiotu> <gracz> i /resetmobedit <gracz>. Pierwsza pozwala nadać wybrany magiczny przedmiot
# wybranemu graczowi, bądź sobie. Druga natomiast resetuje zmienną przechowującą informację czy gracz edytuje jakiegoś potwora w razie błędu.

# 2. Jak używać?
# a) patyk ataku - Patyk ataku pozwala na zaatakowanie jednego moba przez drugiego. Wystarczy tylko, że
# klikniesz lewym przyciskiem myszy na moba który ma atakować, oraz prawym na drugiego który ma być ofiarą.
# b) patyk walki - Patyk walki działa podobnie do poprzedniego, jednak różni się tym, że nie ma w nim ofiary ani
# atakującego. Oba moby ruszają JEDNOCZEŚNIE na siebie. Wystarczy tylko, że klikniesz lewym na pierwszego,
# oraz prawym na druiego.
# c) patyk zarządzania mobami - Patyk różni się od dwóch poprzednich, ponieważ pozwala na zakładanie i zdejmowanie
# zbroji, oraz dawanie i zabieranie przedmiotów do głównej ręki i drugiej ręki. Aby to zrobić, wystarczy, że
# klikniesz prawym przyciskiem myszy jednocześnie kucając.
# d) patyk kopiowania - Patyk pozwala na skopiowanie moba klikając na niego prawym przyciskiem myszy. Wtedy patyk zostaje zastąpiony
# innym itemem który (domyślnie) jest patykiem przechowującym skopiowanego moba. Po kliknięciu na jakiś blok tym patykiem, skopiowany
# wcześniej mob zostaje postawiony w wybranym miejscu.

# 3. Dodatkowe informacje, zaobserwowane podczas testowania skryptu:
# - W wersji 1.0 nie dało się robić niektórych walk, ale od 
# wersji 1.1 można już robić walki między dosłownie wszystkim oprócz między dwoma Wardenami no i zwierzętami które nie potrafią zadać obrażeń.
# - Na zbroję moba można zakładać nie tylko zbroje, ale każdy dostępny item, jednak widoczne będą tylko na głowie.

# Konfiguracja:

options:

    prefix: &3Serwer &e>>

    commandUsage: &cUżycie komendy: /magic <id przedmiotu> <*gracz*>
    commandPermission: serwer.magic
    commandPermissionMessage: &cNie masz permisji!
    commandDescription: Nadaje wybrany magiczny przedmiot wybranemu graczowi lub sobie.
    commandSuccessOther: &aPomyślnie nadałeś magiczny item graczowi &2(G)&a!
    commandSuccessYour: &aPomyślnie nadałeś sobie magiczny item!
    commandOffline: &cNie ma takiego gracza online!
    commandUnknownType: &cRodzaj &4(R) &cnie został rozpoznany!

    command2Usage: &cUżycie komendy: /resetmobedit <gracz>
    command2Permission: serwer.resetmobedit
    command2PermissionMessage: &cNie masz permisji!
    command2Description: Resetuje status edytowania ekwipunku moba w razie błędu.
    command2SuccessOther: &aPomyślnie zresetowałeś status moba graczowi &2(G)&a!
    command2SuccessYour: &aPomyślnie zresetowałeś swój status moba!
    command2Offline: &cNie ma takiego gracza online!

    itemAttack: stick
    itemAttackId: Atak
    itemAttackName: &1Patyk ataku
    itemAttackLore: &bKliknij lewym, aby zaznaczyć atakującego!%nl%&9Kliknij prawym, aby zaznaczyć ofiarę!

    itemFight: stick
    itemFightId: Walka
    itemFightName: &bPatyk walki
    itemFightLore: &bKliknij lewym, aby zaznaczyć pierwszego fightera!%nl%&9Kliknij prawym, aby zaznaczyć drugiego fightera!

    itemModify: stick
    itemModifyId: Ekwipunek
    itemModifyName: &aPatyk zarządzania mobami
    itemModifyLore: &9Kliknij prawym kucając, aby edytować ekwipunek potwora!

    itemCopy: stick
    itemCopyId: Kopiowanie
    itemCopyName: &dPatyk kopiowania mobów
    itemCopyLore: &5Kliknij prawym na moba, aby otrzymac jego kopie!
    itemAfterCopy: stick
    itemAfterCopyName: &dPatyk z mobem
    itemAfterCopyLore: &5Kliknij prawym na blok, aby zespawnować skopiowanego moba!%nl%%nl%&r(ID)

    attackerUnSelected: &cNie zaznaczyłeś atakującego!
    firstUnSelected: &cNie zaznaczyłeś pierwszego zawodnika!

    firstAttackSuccess: &aPomyślnie zaznaczyłeś atakującego.
    secondAttackSuccess: &aPomyślnie zaznaczyłeś ofiarę, rozpoczynając atak!

    firstFightSuccess: &aPomyślnie zaznaczyłeś pierwszego zawodnika walki.
    secondFightSuccess: &aPomyślnie zaznaczyłeś drugiego zawodnika walki, rozpoczynając tą walkę!

    alreadyMobEditing: &cTen mob jest teraz edytowany przez innego gracza.

    copiedSuccess: &aSkopiowano moba w patyku!

# Skrypt - jeśli nie umiesz pisać skryptów w języku Skript, lepiej nie edytuj nic poniżej.

on damage of entity:
    attacker's tool is {@itemAttack} named "{@itemAttackName}" with lore "{@itemAttackLore}":
        cancel event
        set {attackone::%attacker%} to uuid of victim
        send "{@prefix} {@firstAttackSuccess}" to the attacker
    attacker's tool is {@itemFight} named "{@itemFightName}" with lore "{@itemFightLore}":
        cancel event
        set {fightone::%attacker%} to uuid of victim
        send "{@prefix} {@firstFightSuccess}" to the attacker

on rightclick on entity:
    player's tool is {@itemAttack} named "{@itemAttackName}" with lore "{@itemAttackLore}":
        if {attackone::%player%} is set:
            send "{@prefix} {@secondAttackSuccess}" to the player
            set {_at1} to {attackone::%player%} parsed as entity
            set target of {_at1} to event-entity
        else:
            send "{@prefix} {@attackerUnSelected}" to the player
            stop
    player's tool is {@itemFight} named "{@itemFightName}" with lore "{@itemFightLore}":
        if {fightone::%player%} is set:
            send "{@prefix} {@secondFightSuccess}" to the player
            set {_fi1} to {fightone::%player%} parsed as entity
            set target of {_fi1} to event-entity
            set target of event-entity to {_fi1}
            send "{@prefix} {@firstUnSelected}" to the player
            stop
        else:
            send "{@prefix} {@firstUnSelected}" to the player
            stop
    player's tool is {@itemModify} named "{@itemModifyName}" with lore "{@itemModifyLore}":
        player is sneaking
        {editing::%uuid of event-entity%} is not true:
            set {editing::%uuid of event-entity%} to true
            set {_} to chest inventory with 3 rows named "&3Eq moba &a%uuid of event-entity%"
            set {_n} to -1
            loop 27 times:
                add 1 to {_n}
                set slot {_n} of {_} to gray stained glass pane
            set slot 10 of {_} to helmet of event-entity
            set slot 11 of {_} to chestplate of event-entity
            set slot 12 of {_} to leggings of event-entity
            set slot 13 of {_} to boots of event-entity
            set slot 14 of {_} to tool of event-entity
            set slot 15 of {_} to off hand tool of event-entity
            open {_} to player
            stop
        else:
            send "{@prefix} {@alreadyMobEditing}" to the player
            stop
    player's tool is {@itemCopy} named "{@itemCopyName}" with lore "{@itemCopyLore}":
        set {_id} to random integer between 1000000000 and 9999999999
        add {_id} to {ids::*}
        set {mobtype::%{_id}%} to type of event-entity
        set {mobhelmet::%{_id}%} to helmet of event-entity
        set {mobchest::%{_id}%} to chestplate of event-entity
        set {moblegs::%{_id}%} to leggings of event-entity
        set {mobboots::%{_id}%} to boots of event-entity
        set {mobtool::%{_id}%} to tool of event-entity
        set {mob2tool::%{_id}%} to off hand tool of event-entity
        set {_nil} to "{@itemAfterCopyLore}"
        replace all "(ID)" in {_nil} with "%{_id}%"
        set player's tool to {@itemAfterCopy} named "{@itemAfterCopyName}" with lore "%{_nil}%"
        send "{@prefix} {@copiedSuccess}" to the player
        stop

on inventory click:
    name of event-inventory contains "&3Eq moba &a"
    event-inventory is not player's inventory
    clicked slot is not 10 or 11 or 12 or 13 or 14 or 15:
        cancel event

on inventory close:
    name of event-inventory contains "&3Eq moba &a"
    event-inventory is not player's inventory
    set {_n} to name of event-inventory
    replace all "&3Eq moba &a" in {_n} with ""
    clear {editing::%{_n}%}
    set {_n} to {_n} parsed as entity
    set helmet of {_n} to slot 10 of event-inventory
    set chestplate of {_n} to slot 11 of event-inventory
    set leggings of {_n} to slot 12 of event-inventory
    set boots of {_n} to slot 13 of event-inventory
    set tool of {_n} to slot 14 of event-inventory
    set off hand tool of {_n} to slot 15 of event-inventory

command magic <text> [<offline player=%sender%>]:
    permission: {@commandPermission}
    permission message: {@prefix} {@commandPermissionMessage}
    description: {@commandDescription}
    usage: {@prefix} {@commandUsage}
    trigger:
        if arg-1 is not "{@itemAttackId}" or "{@itemFightId}" or "{@itemModifyId}" or "{@itemCopyId}":
            set {_commandUnknownType} to "{@commandUnknownType}"
            replace all "(R)" in {_commandUnknownType} with arg-1
            send "{@prefix} %{_commandUnknownType}%" to the sender
            stop
        if arg-2 is not sender:
            if arg-2 is online:
                set {_arg2} to arg-2
                set {_arg2} to {_arg2} parsed as player
                set {_commandSuccessOther} to "{@commandSuccessOther}"
                replace all "(P)" in {_commandSuccessOther} with "%arg-2%"
                if arg-1 is "{@itemAttackId}":
                    give 1 of {@itemAttack} named "{@itemAttackName}" with lore "{@itemAttackLore}" to {_arg2}
                    send "{@prefix} %{_commandSuccessOther}%" to the sender
                if arg-1 is "{@itemFightId}":
                    give 1 of {@itemFight} named "{@itemFightName}" with lore "{@itemFightLore}" to {_arg2}
                    send "{@prefix} %{_commandSuccessOther}%" to the sender
                if arg-1 is "{@itemCopyId}":
                    give {@itemCopy} named "{@itemCopyName}" with lore "{@itemCopyLore}" to player
                    send "{@prefix} {@commandSuccessOther}" to the sender
                    stop
            else:
                send "{@prefix} {@commandOffline}" to the sender
        else:
            if arg-1 is "{@itemAttackId}":
                give 1 of {@itemAttack} named "{@itemAttackName}" with lore "{@itemAttackLore}" to player
                send "{@prefix} {@commandSuccessYour}" to the sender
            if arg-1 is "{@itemFightId}":
                give 1 of {@itemFight} named "{@itemFightName}" with lore "{@itemFightLore}" to player
                send "{@prefix} {@commandSuccessYour}" to the sender
            if arg-1 is "{@itemModifyId}":
                give {@itemModify} named "{@itemModifyName}" with lore "{@itemModifyLore}" to player
                send "{@prefix} {@commandSuccessYour}" to the sender
            if arg-1 is "{@itemCopyId}":
                give {@itemCopy} named "{@itemCopyName}" with lore "{@itemCopyLore}" to player
                send "{@prefix} {@commandSuccessYour}" to the sender
            stop

command resetmobedit [<offline player=%sender%>]:
    permission: {@command2Permission}
    permission message: {@prefix} {@command2PermissionMessage}
    description: {@command2Description}
    usage: {@prefix} {@command2Usage}
    trigger:
        arg-1 is online:
            loop all entities:
                loop-entity is not player
                clear {editing::%uuid of loop-entity%}
            arg-1 is sender:
                send "{@prefix} {@command2SuccessYour}" to the player
                stop
            set {_r} to "{@command2SuccessOther}"
            replace all "(G)" in {_r} with "%arg-1%"
            send "{@prefix} %{_r}%" to the player
            stop
        else:
            send "{@prefix} {@command2Offline}" to the player
            stop

on rightclick:
    clicked block is not air or lava or water
    name of player's tool is "{@itemAfterCopyName}"
    set {_id} to line 3 of lore of player's tool parsed as integer
    set {_tb} to location of event-block
    add 1 to y-coordinate of {_tb}
    spawn {mobtype::%{_id}%} at {_tb}
    set helmet of last spawned entity to {mobhelmet::%{_id}%}
    set chestplate of last spawned entity to {mobchest::%{_id}%}
    set leggings of last spawned entity to {moblegs::%{_id}%}
    set boots of last spawned entity to {mobboots::%{_id}%}
    set tool of last spawned entity to {mobtool::%{_id}%}
    set off hand tool of last spawned entity to {mob2tool::%{_id}%}

on tab complete of "/magic":
    set tab completion for position 1 to "{@itemAttackId}" and "{@itemFightId}" and "{@itemModifyId}" and "{@itemCopyId}"

# # # # # # # # # # # # # # #
# MobManager 1.1 by TeZetYT #
# # # # # # # # # # # # # # #