#==========================#
#       Skrypt Życie       #
#                          #
#          Autor           #
#       THEzombiePL        #
#                          #
#         Kontakt          #
#         Discord          #
#     THEzombiePL#2308     #
#==========================#
options:
#==========================#
#=== Startowa ilość żyć ===#
#==========================#
 zycia.start: 3
#==========================#
#=== Domyślny czas bana ===#
#==========================#
 czasbana: 30m
#==========================#
#===    Nie zmieniać    ===#
#==========================#
 wersja: 1.2
#==========================#
on load:
 set {wwersja} to formatted text from "https://pastebin.com/raw/wEsZC7Ca"
 if {czasbana} is not set:
  set {czasbana} to "{@czasbana}"
 if {resetzyc} is true:
  set {resetzyc} to false
 if {zyciastartowe} is not set:
  set {zyciastartowe} to {@zycia.start}
 wait 10 ticks
 if "%{wwersja}%" is "{@wersja}":
  send "[Życia]INFO: Skrypt został pomyślnie załadowany." to console
 else:
  send "[Życia]ERROR: wersja została zmieniona." to console
on join:
 if {zycia::zyciaa.%player%} <= 0:
  set {zycia::zyciaa.%player%} to {zyciastartowe} 
  send "&7Twoje &cżycia &7zostały zresetowane do: &6&l%{zyciastartowe}%"
 if {zycia::zyciaa.%player%} is not set:
  set {zycia::zyciaa.%player%} to {zyciastartowe}
  send "&7Twoje &cżycia &7zostały ustawione na:&6 %{zyciastartowe}%"
 send "&7Liczba twoich &cżyć &7to &6&l%{zycia::zyciaa.%player%}%"
on death:
 if victim is player:
  remove 1 from {zycia::zyciaa.%player%}
  message "&7Straciłeś &9&l1 &cżycie!"
  wait 5 ticks
  message "&7Liczba pozostałych &cżyć&7: &9&l%{zycia::zyciaa.%player%}%" to player
  if {zycia::zyciaa.%player%} <= 0:
   send "&7Pożegnaj sie z serwerem. Zostaniesz zbanowany na %{czasbana}%&7." to player
   send "&7Gracz &e&l%player% &7stracił swoje wszystkie życia!" and "&7Możesz oddać mu swoje życie! &f&l/oddaj %player%" to all players
   wait 30 seconds
   if {zycia::zyciaa.%player%} <= 0:
    execute console command "/tempban %player% %{czasbana}% Skończyły ci się życia!"
    broadcast "&7Gracz &e&l%player% &7został zbanowany na &9%{czasbana}%&7."
command /zycia [<text>]:
 trigger:
  if arg 1 is not set:
   send "&7Posiadasz &czyc&7: &6&l%{zycia::zyciaa.%player%}%"
  if arg 1 is set:
   if player has permission "tzplife.admin":
    send "&e&l%arg 1% &7posiada &czyc&7: &9&l%{zycia::zyciaa.%arg 1%}%" 
command /oddaj [<player>]:
 usage: &7Użycie: &e/oddaj nick
 trigger:
  if arg 1 is set:
   if {zycia::zyciaa.%player%} >= 2:
    add 1 to {zycia::zyciaa.%arg 1%}
    remove 1 from {zycia::zyciaa.%player%}
    send "&aUleczyłeś &7gracza &e&l%arg 1%"
   else:
    send "&7Potrzebujesz minimum &9&l2 &cżycia &7do uleczenia kogoś"
  if arg 1 is not set:
   send "&7Użycie: &e/oddaj nick"
command /dodaj [<player>]:
 permission: tzplife.admin
 permission message: &cNie masz pozwolenia na używanie tej komendy
 trigger:
  if arg 1 is set:
   if player has permission "script.admin":
    add 1 to {zycia::zyciaa.%arg 1%}
    send "&aDodałeś &cżycie &7dla &e&l%arg 1%"
  if arg 1 is not set:
   send "&7Użycie: &e/dodaj nick"
command /zabierz [<player>]:
 permission: tzplife.admin
 permission message: &cNie masz pozwolenia na używanie tej komendy
 trigger:
  if arg 1 is set:
   remove 1 from {zycia::zyciaa.%arg 1%}
   send "&cZabrałeś &cżycie &7od &e&l%arg 1%"
   if {zycia::zyciaa.%arg 1%} <= 0:
    send "&7Pożegnaj sie z serwerem. Zostaniesz zbanowany na %{czasbana}%" to arg 1
    send "&7Gracz &e&l%arg 1% &7stracił swoje wszystkie życia!" and "&7Możesz oddać mu swoje życie! &f&l/oddaj %arg 1%" to all players
    wait 30 seconds
    if {zycia::zyciaa.%arg 1%} <= 0:
     execute console command "/tempban %arg 1% %{czasbana}% Skończyły ci się życia!"
     send "&7Gracz &e&l%arg 1% &7został zbanowany na &9%{czasbana}%&7." to all players
  if arg 1 is not set:
   send "&7Użycie: &e/zabierz nick"
command /tzplife [<text=help>] [<text>] [<text>]:
 aliases: /life, /lifes, /lifemc, /lifetzp, /zycie, /życie
 trigger:
  if arg 1 is "komendy" or "help" or "pomoc":
   send "&5================ &3&lŻycie &2{@wersja} &5================" and "&5============ &9&lKomendy dla Gracza&5 ============" and "&f/zycia &7- pokazuje ilość twoich żyć." and "&f/oddaj &e&lnick &7- daje twoje jedno życie graczowi." and "&f/zycie &e&lhelp &7- pokazuje dostępne komendy."
   if player doesn't have permission "tzplife.admin":
    send "&5=========================================="
   if player has permission "tzplife.admin":
    send "&5========= &9&lKomendy dla Administratora&5=========" and "&f/zycie &e&lwersja &7- sprawdza wersję skryptu." and "&f/zycie &e&lreload &7- przeładowuje skrypt" and "&f/zycie &e&lczasbana &7- ustawienia dotyczące czasu bana." and "&f/zycie &e&lzyciastart &7- ustawienia dotyczące żyć." and "&f/dodaj &e&lnick &7- dodaje jedno życie graczowi." and "&f/zabierz &e&lnick &7- zabiera jedno życie graczowi." and "&f/miksturazycia &7- daje miksturę życia." and "&5=========================================="
  if arg 1 is "reload":
   if player has permission "tzplife.admin":
    set {reload} to "true"
    send "[&3&lŻycie&r]&6Przeładowywanie skryptu"
    execute player command "/sk reload %script%"
  if arg 1 is "wersja":
   if player has permission "tzplife.admin":
    send "[&3&lŻycie&r] &eNajnowsza wersja skryptu: &a%{wwersja}%"
    if "{@wersja}" is not "%{wwersja}%":
     send "[&3&lŻycie&r] &eTwoja wersja skryptu: &c{@wersja}" and "[&3&lŻycie&r] &eNajnowszą wersję skryptu znajdziesz tutaj&6&l: <tooltip: &dKliknij tutaj, aby pobrać najnowszą wersję><link:https://pastebin.com/eCNPFn90>&b[&aKliknij tutaj&b]"
    if "{@wersja}" is "%{wwersja}%":
     send "[&3&lŻycie&r] &eTwoja wersja skryptu: &a{@wersja}"
  if arg 1 is "czasbana":
   if player has permission "tzplife.admin":
    if arg 2 is not "sprawdz" or "ustaw":
     send "&e/zycie czasbana sprawdz &7- pokazuje czas bana." and "&e/zycie czasbana ustaw &6<czas> &7- ustawia czas bana."
    if arg 2 is "sprawdz":
     send "&7Czas bana za stracenie wszystkich &cżyć&7: &6%{czasbana}%"
    if arg 2 is "ustaw":
     if arg 3 is not set:
      send "&7Prawidłowe użycie: &e/zycie czasbana ustaw &6<czas>"
     if arg 3 is set:
      set {czasbana} to arg 3
      send "&7Ustawiono czas bana na: &6%{czasbana}%" to player
  if arg 1 is "zyciastart":
   if player has permission "tzplife.admin":
    if arg 2 is not "sprawdz" or "ustaw":
     send "&e/zycie zyciastart sprawdz &7- pokazuje startową ilość żyć." and "&e/zycie zyciastart ustaw &6<czas> &7- ustawia startową ilość żyć."
    if arg 2 is "sprawdz":
     send "&7Startowa ilość &cżyć&7: &6%{zyciastartowe}%"
    if arg 2 is "ustaw":
     if arg 3 is not set:
      send "&7Prawidłowe użycie: &e/zycie zyciastart ustaw &6ilość"
     if arg 3 is set:
      set {zyciastartowe} to arg 3 parsed as number
      send "&7Ustawiono ilość startową &cżyć &7na: &6%{zyciastartowe}%" to player
on script load:
 if {reload} is "true":
  send "&7[&3&lŻycie&7]&aZaładowano pomyślnie." to ops
  set {reload} to "false"
on script unload:
 if {reload} is "false":
  send "&7[&3&lŻycie&7]&6Przeładowywanie skryptu." to ops
  set {reload} to "true"
on join:
 wait 3 seconds
 if player have permission "tzplife.admin":
  if "%{wwersja}%" is not "{@wersja}":
   send "[&3&lŻycie&r] &eSkrypt został zaktualizowany! <tooltip: &dKliknij tutaj, aby pobrać najnowszą wersję><link:https://pastebin.com/eCNPFn90>&8[&aKliknij tutaj&8]"
command /miksturazycia [<text>]:
 permission: tzplife.admin
 permission message: &cNie masz pozwolenia na używanie tej komendy
 trigger:
  send "&2Przyznano &9Miksturę &cŻycia."
  give 1 potion named "&9Mikstura &cŻycia" with lore "&2Po wypiciu tej mikstury otrzymujesz &61 &2dodatkowe &cżycie&2." to player
on consume:
 if player's tool is potion named "&9Mikstura &cŻycia" with lore "&2Po wypiciu tej mikstury otrzymujesz &61 &2dodatkowe &cżycie&2.":
  add 1 to {zycia::zyciaa.%player%}
  send "&7Otrzymujesz &61 &7dodatkowe &c&lżycie." and "&7Wpisz komendę &e/zycia&7, aby sprawdzić ilość żyć."


command /resetujzycia [<text>]:
 permission: tzplife.admin
 permission message: &cNie masz pozwolenia na używanie tej komendy
 trigger:
  set {gracz} to player
  if {resetzyc} is false:
   set {resetzyc} to true
   send "&aWpisz komendę &e/resetujzycia &aponownie w ciągu &65 sekund&a, aby zresetować &cżycia &awszystkich graczy."
   stop
  if {resetzyc} is true:
   clear {zycia::*}
   set {resetzyc} to false
   send "&2Zresetowano &cżycia &2wszystkich graczy."
  wait 5 seconds
  set {resetzyc} to false