#AxNameMc - skrypt na nagrody za polubienie na namemc
#Nowy skrypt: https://skript.pl/temat/39421-axnamemc-skrypt-na-nagrody-za-polubienie-v2

on load:
    if yaml value "Serwer" from file "AxNameMc/config.yml" is not set:
        create file "plugins/Skript/scripts/AxNameMc/config.yml"
        wait 10 tick
        download from "https://pastebin.com/raw/WdMCNu6F" to "plugins/Skript/scripts/AxNameMc/config.yml"
        send "&7Pobrano konfiguracje &aAxNameMc" to console
    set {AxNameMc::serwer} to yaml value "Serwer" from file "AxNameMc/config.yml"
    set {AxNameMc::time} to yaml value "Cooldown" from file "AxNameMc/config.yml"
    set {AxNameMc::time} to {AxNameMc::time} parsed as time span
    send "&7Poprawnie zaladowano ustawienia &aAxNameMc" to console
command /namemc [<text="help">]:
    trigger:
        if arg is "odbierz":
            if {AxNameMc::pl::%player%} is not set:
                set {AxNameMc::pl::%player%} to now
                remove {AxNameMc::time} from {AxNameMc::pl::%player%}
            if difference between now and {AxNameMc::pl::%player%} >= {AxNameMc::time}:
                if text from "https://api.namemc.com/server/%{AxNameMc::serwer}%/likes?profile=%player's uuid%" is "true":
                    loop (yaml list "Message.Succes" from file "AxNameMc/config.yml"):
                        send colored ("%loop-value%")
                    loop (yaml list "Awards" from file "AxNameMc/config.yml"):
                        add ("%loop-value%" parsed as item) to player
                    set {AxNameMc::pl::%player%} to now
                else:
                    loop (yaml list "Message.Failed" from file "AxNameMc/config.yml"):
                        send colored ("%loop-value%")
            else:
                loop (yaml list "Message.Failed-Cooldown" from file "AxNameMc/config.yml"):
                    send colored ("%loop-value%")
        else:
            loop (yaml list "Message.Info" from file "AxNameMc/config.yml"):
                send colored ("%loop-value%")