#Autor: MarcusSlover
#Wersja: 1.0
#Proszę o nie kopiowanie, bądź zmienianie autora!

variables:

	{ilosc.warpow::%player%} = 0

options:

# Ustawienia

	prefix: &e[&bs&3&lWarp&e]
	nazwa.menu: &e[&bs&3&lWarp&e] &rMenu
	nazwa.menu.moje.warpy: &e[&bs&3&lWarp&e] &rMoje Warpy
	nazwa.menu.publiczne.warpy: &e[&bs&3&lWarp&e] &rPubliczne Warpy
	nazwa.menu.wybrany.warp: &e[&bs&3&lWarp&e] &rWarp
	komenda: warp
	
	moje.warpy: snowball named "&e[&aMoje Warpy&e]" with lore "&3&l* &bKliknij, aby otworzyć!"
	publiczne.warpy: slimeball named "&e[&6Publiczne Warpy&e]" with lore "&3&l* &bKliknij, aby otworzyć!"
	powrot: arrow named "&e[&cPowrót&e]" with lore "&3&l* &bKliknij, aby powrócić!"
	twoje.warpy: skull of {_p} named "&e[&aTwoje Warpy&e]"
	pusto: black glass pane block named "&e[&cPusto&e]"
	warpy: light blue glass pane block named "&e[&fWarp %loop-value%&e]" with lore "&3&l* &bKliknij, aby otworzyć!"
	dodaj.warp: light green dye named "&e[&aStwórz Warp&e]" with lore "&3&l* &bKliknij, aby stowrzyć!"
	usun.warp: red dye named "&e[&cUsuń Warp&e]" with lore "&3&l* &bKliknij, aby usunąć!"
	teleportacja: ender pearl named "&e[&9Teleportacja&e]" with lore "&3&l* &bKliknij, aby się przeteleportować!"
	status.prywatny: light green dye named "&e[&dStatus&e]" with lore "&eAktualny Status: &aPrywatny||&3&l* &bKliknij, aby zmienić!"
	status.publiczny: orange dye named "&e[&dStatus&e]" with lore "&eAktualny Status: &6Publiczny||&3&l* &bKliknij, aby zmienić!"
	warp.publiczny: light blue glass pane block named "&e[&6Warp %loop-value%&e]" with lore "&eTwórca: &f%{tworca::%loop-value%}%||&3&l* &bKliknij, aby się przeteleportować!"
	
# Wiadomości 

	brak.permisji: &e[&bs&3&lWarp&e] &cNie posiadasz tej permisji!
	utworzenie.warpa: &aUtworzyłeś warp!
	usuniencie.warpa: &aUsunąłeś warp!
	pytanie.tworzenie.warpa: &dJak chciałbyś nazwać ten warp?
	pytanie.usuwanie.warpa: &dJakiego warp chciałbyś usunąć?
	posiadanie.warpu: &cPosiadasz już warp o takiej nazwie!
	brak.warpu: &cNie posiadasz warpu o takiej nazwie!
	teleport: &aPrzeteleportowano!
	maksymalna.ilosc.warpow: &cPosiadasz maksymalną ilość warpów!
	
# Permisje
	
	permisja.komenda: swarp.komenda
	
# Funkcje (Wolał bym żeby nic tu nie było zmieniane)

function menu(p: player):
	open chest with 3 rows named "{@nazwa.menu}" to {_p}
	set slot 12 of {_p}'s current inventory to {@moje.warpy}
	set slot 14 of {_p}'s current inventory to {@publiczne.warpy}
	
function menu_moje_warpy(p: player):
	open chest with 4 rows named "{@nazwa.menu.moje.warpy}" to {_p}
	set slot 4 of {_p}'s current inventory to {@twoje.warpy}
	set slot 4*9-5 of {_p}'s current inventory to {@powrot}
	set slot 20 of {_p}'s current inventory to {@dodaj.warp}
	set slot 24 of {_p}'s current inventory to {@usun.warp}
	set {_n} to 10
	loop 7 times:
		set slot {_n} of {_p}'s current inventory to {@pusto}
		add 1 to {_n}
	set {_n} to 10
	loop {warpy.%{_p}%::*}:
		set slot {_n} of {_p}'s current inventory to {@warpy}
		add 1 to {_n}
		
function menu_wybrany_warp(p: player , warp: text):
	open chest with 3 rows named "{@nazwa.menu.wybrany.warp} %{_warp}%" to {_p}
	set {_p}'s current inventory's slot 11 to {@teleportacja}
	{status.%{_p}%::%{_warp}%} is "prywatny":
		set {_p}'s current inventory's slot 15 to {@status.prywatny}
	{status.%{_p}%::%{_warp}%} is "publiczny":
		set {_p}'s current inventory's slot 15 to {@status.publiczny}
	set slot 3*9-5 of {_p}'s current inventory to {@powrot}
	stop
	
function menu_publiczne_warpy(p: player):
	open chest with 6 rows named "{@nazwa.menu.publiczne.warpy}" to {_p}
	set {_p}'s current inventory's slot 49 to {@powrot}
	set {_n} to 0
	loop {warpy.publiczne::*}:
		{_n} <= 43:
			set {_p}'s current inventory's slot {_n} to {@warp.publiczny}
		add 1 to {_n}
		
command /{@komenda} [<text>]:
	permission: {@permisja.komenda}
	permission message: {@brak.permisji}
	trigger:
		arg is not set:
			menu(player)
			stop
			
on inventory click:
	"%inventory name of player's current inventory%" contains "{@nazwa.menu.publiczne.warpy}":
		cancel event
		player's current inventory's slot slot is {@powrot}:
			menu(player)
			stop
		player's current inventory's slot slot is light blue glass pane block:
			set {_nazwa} to uncoloured player's current inventory's slot slot's name
			replace all "[" and "Warp" and "]" and " " with "" in {_nazwa}
			set {_tworca} to uncoloured line 1 of player's current inventory's slot slot's lore
			replace all "Twórca:" and " " with "" in {_tworca}
			set {_tworca} to {_tworca} parsed as player
			{warp.%{_tworca}%::%{_nazwa}%} is set:
				teleport player to {warp.%{_tworca}%::%{_nazwa}%}
				send "{@prefix} {@teleport}"
				stop	
	"%inventory name of player's current inventory%" contains "{@nazwa.menu}":
		cancel event
		player's current inventory's slot slot is {@moje.warpy}:
			menu_moje_warpy(player)
			stop
		player's current inventory's slot slot is {@publiczne.warpy}:
			menu_publiczne_warpy(player)
			stop
	"%inventory name of player's current inventory%" contains "{@nazwa.menu.moje.warpy}":
		cancel event
		player's current inventory's slot slot is {@powrot}:
			menu(player)
			stop
		player's current inventory's slot slot is {@dodaj.warp}:
			close player's inventory
			delete {usuwanie.warpa::%player%}
			set {tworzenie.warpa::%player%} to true
			send "{@prefix} {@pytanie.tworzenie.warpa}"
			stop
		player's current inventory's slot slot is {@usun.warp}:
			close player's inventory
			delete {tworzenie.warpa::%player%}
			set {usuwanie.warpa::%player%} to true
			send "{@prefix} {@pytanie.usuwanie.warpa}"
			stop
		player's current inventory's slot slot is light blue glass pane block:
			set {_nazwa} to uncoloured player's current inventory's slot slot's name
			replace all "[" and "Warp" and "]" and " " with "" in {_nazwa}
			{warp.%player%::%{_nazwa}%} is set:
				menu_wybrany_warp(player , "%{_nazwa}%")
				stop
	"%inventory name of player's current inventory%" contains "{@nazwa.menu.wybrany.warp}":
		cancel event
		player's current inventory's slot slot is {@powrot}:
			menu_moje_warpy(player)
			stop
		player's current inventory's slot slot is {@teleportacja}:
			set {_nazwa} to "%inventory name of player's current inventory%"
			replace all "{@nazwa.menu.wybrany.warp}" and " " with "" in {_nazwa}
			{warp.%player%::%{_nazwa}%} is set:
				teleport player to {warp.%player%::%{_nazwa}%}
				send "{@prefix} {@teleport}"
				stop
		player's current inventory's slot slot is {@status.prywatny}:
			set {_nazwa} to "%inventory name of player's current inventory%"
			replace all "{@nazwa.menu.wybrany.warp}" and " " with "" in {_nazwa}
			{warp.%player%::%{_nazwa}%} is set:
				set {status.%player%::%{_nazwa}%} to "publiczny"
				loop all players:
					"%inventory name of loop-player's current inventory%" contains "{@nazwa.menu.publiczne.warpy}":
						menu_publiczne_warpy(loop-player)
				add "%{_nazwa}%" to {warpy.publiczne::*}
				menu_wybrany_warp(player , "%{_nazwa}%")
				stop
		player's current inventory's slot slot is {@status.publiczny}:
			set {_nazwa} to "%inventory name of player's current inventory%"
			replace all "{@nazwa.menu.wybrany.warp}" and " " with "" in {_nazwa}
			{warp.%player%::%{_nazwa}%} is set:
				set {status.%player%::%{_nazwa}%} to "prywatny"
				loop all players:
					"%inventory name of loop-player's current inventory%" contains "{@nazwa.menu.publiczne.warpy}":
						menu_publiczne_warpy(loop-player)
				remove "%{_nazwa}%" from {warpy.publiczne::*}
				menu_wybrany_warp(player , "%{_nazwa}%")
				stop
			
on chat:
# Dodawnie
	{tworzenie.warpa::%player%} is true:
		cancel event
		delete {tworzenie.warpa::%player%}
		{ilosc.warpow::%player%} < 7:
			{warp.%player%::%message%} is not set:
				add 1 to {ilosc.warpow::%player%}
				set {warp.%player%::%message%} to player's location
				set {tworca::%message%} to player
				set {status.%player%::%message%} to "prywatny"
				add "%message%" to {warpy.%player%::*}
				send "{@prefix} {@utworzenie.warpa}"
				menu_moje_warpy(player)
				stop
			else:
				send "{@prefix} {@posiadanie.warpu}"
				menu_moje_warpy(player)
				stop
		else:
			send "{@prefix} {@maksymalna.ilosc.warpow}"
			menu_moje_warpy(player)
			stop
# Usuwanie
	{usuwanie.warpa::%player%} is true:
		cancel event
		delete {usuwanie.warpa::%player%}
		{warp.%player%::%message%} is set:
			remove 1 from {ilosc.warpow::%player%}
			remove "%message%" from {warpy.publiczne::*}
			delete {status.%player%::%message%}
			delete {warp.%player%::%message%}
			delete {tworca::%message%}
			remove "%message%" from {warpy.%player%::*}
			send "{@prefix} {@usuniencie.warpa}"
			menu_moje_warpy(player)
			stop
		else:
			send "{@prefix} {@brak.warpu}"
			menu_moje_warpy(player)
			stop
			
on quit:
	delete {tworzenie.warpa::%player%}
	delete {usuwanie.warpa::%player%}
	delete {zmienianie.nazwy::%player%}
	stop