code.skript.pl - kod HUcqN3YQ

#Zwycięzca konkursu SkriptJam w Maju 2020

options:
    test-Fast: ghast tear named "&bSzybki test" with lore " &8Szybki test &a70%% &8na wykrycie zakazenia" and " &8Uderz gracza aby wykonac test"
    test-Prec: ghast tear named "&aDokladny test" with lore " &8Dokladny test &a90%% &8na wykrycie zakazenia" and " &8Uderz gracza aby wykonac test"
function getProcInfect(p: player, x: number) :: number:
    return 0 if {_p} is wearing all leather armour named "&6Kombinezon"
    return (5 -  {_x}/2) if {_p}'s helmet is leather helmet
    return (10 -  {_x}/2)
function getProcSymptom(p: player) :: number:
    return 0 if {Ax::NoSymptoms::*} contain {_p}
    return 10
function infect(p: player):
    if {Ax::cases::*} contain {_p}:
        stop
    add {_p} to {Ax::cases::*}
    chance of 25%:
        add {_p} to {Ax::NoSymptoms::*}
function getBoolText(b: boolean) :: text:
    return "&aPozytywny" if {_b}
    return "&cNegatywny"
function test(p1: player, p: player, n: number):
    set {_s} to false
    if {Ax::cases::*} contain {_p}:
        set {_s} to true
    if {_n} is 1:
        chance of 35%:
            set {_s} to !{_s}
        send "&7Wynik szybkiego testu &8(70%%) &7wyszedl: %getBoolText({_s})%" to {_p1}
    if {_n} is 2:
        chance of 10%:
            set {_s} to !{_s}
        send "&7Wynik dokladnego testu &8(90%%) &7wyszedl: %getBoolText({_s})%" to {_p1}
on join:
    send "" and " &7W zwiazku z panujaca epidemia koronawirusa, kazdy powinien nosic maseczki oraz nie przebywac w grupie ludzi" and "&7Zachowaj odstep min 2 kratek od innych graczy!" and ""
    while player is online:
        if {Ax::cases::*} contain player:
            loop all players in radius 3 around player:
                chance of getProcInfect(player, (distance between player and loop-player))%:
                    infect(loop-player)
            chance of getProcSymptom(player)%:
                if (random integer between 0 and 2) is 1:
                    apply nausea 2 to player for 5 second
                else:
                    set player's walk speed to 0.25
                    wait 0.2 second
                    reset player's walk speed
                    wait 0.2 second
        wait 10 second
on damage of player:
    if attacker is player:
        if attacker's tool is {@test-Fast}:
            test(attacker, victim, 1)
        if attacker's tool is {@test-Prec}:
            test(attacker, victim, 2)
every minute:
    send "" and " &7W zwiazku z panujaca epidemia koronawirusa, kazdy powinien nosic maseczki oraz nie przebywac w grupie ludzi" and "&7Zachowaj odstep min 2 kratek od innych graczy!" and "" to all players
command /koronka [<text="help">] [<player>]:
    permission: *
    trigger:
        if arg 1 is "help":
            send "&a/koronka zaraz <gracz> &7- Sztucznie zaraza gracza"
            send "&a/koronka wylecz <gracz>&7- Leczy gracza"
            send "&a/koronka cases &7- Lista zarazonych"
            send "&a/koronka nosymp &7- Lista osob zarazonych bez objawow"
            send "&a/koronka symp &7- Lista osob zarazonych z objawami"
            send "&a/koronka test1 &7- Daje szybki test 50%% na poprawny wynik"
            send "&a/koronka test2 &7- Daje dokladny test 99%% na poprawny wynik"
            send "&a/koronka izoluj &7- Izoluje gracza"
            send "&a/koronka izolatka &7- Ustawia miejsce izolatki"
            stop
        if arg 1 is "cases":
            send "&7Osoby zarazone:"
            send "&c%{Ax::cases::*}%"
            stop
        if arg 1 is "nosymp":
            send "&7Osoby zarazone bez objawow:"
            send "&c%{Ax::NoSymptoms::*}%"
            stop
        if arg 1 is "symp":
            send "&7Osoby zarazone z objawami:"
            set {_x::*} to {Ax::cases::*}
            remove {Ax::NoSymptoms::*} from {_x::*}
            send "&c%{_x::*}%"
            stop
        if arg 1 is "test1":
            add {@test-Fast} to player
            send "&7Dostales szybki test"
            stop
        if arg 1 is "test2":
            add {@test-Prec} to player
            send "&7Dostales dokladny test"
            stop
        if arg 1 is "izolatka":
            set {Ax::izolatka} to location of player
            send "&7Ustawiles miejsce izolatki!"
            stop
        if arg 2 is not set:
            send "&7Podaj gracza!"
            stop
        if arg 1 is "izoluj":
            equip arg 2 with all leather armour named "&6Kombinezon"
            teleport arg 2 to {Ax::izolatka}
            send "&7Odizolowano gracza %arg 2%"
        if arg 1 is "wylecz":
            remove arg 2 from {Ax::cases::*} and {Ax::NoSymptoms::*}
            send "&7Wyleczono gracza %arg 2%"
        if arg 1 is "zaraz":
            infect(arg 2)
            send "&7Zaraziles gracza %arg 2%"