code.skript.pl - kod JLkbttr3

function kGame_reloadYaml(t: text="") :: boolean:
    set {_kGameUtil} to kGame_getPath("kGame_Util", "mainInventory")
    set {kGame::mainInventory::inventory::name} to yaml value "inventory.name" from {_kGameUtil}
    set {kGame::mainInventory::inventory::item::empty} to yaml value "inventory.empty" from {_kGameUtil}
    set {kGame::mainInventory::inventory::rows} to yaml value "inventory.rows" from {_kGameUtil}
    loop yaml nodes "inventory" from {_kGameUtil}:
        if loop-value is not "name" or "rows" or "empty":
            set {_yml} to yaml value "inventory.%loop-value%.item" from {_kGameUtil}
            set {kGame::registersGame::%loop-value%::item} to kGame_getItemFromText({_yml})
            set {kGame::registersGame::%loop-value%::slot} to yaml value "inventory.%loop-value%.slot" from {_kGameUtil}
    return true
function kGame_getInventory(p: player) :: inventory:
    set {_rows} to {kGame::mainInventory::inventory::rows}
    set {_x} to chest with {_rows} rows named coloured {kGame::mainInventory::inventory::name}
    set {_empty} to kGame_getItemFromText({kGame::mainInventory::inventory::item::empty})
    loop {_rows}*9 times:
        set slot loop-number - 1 of {_x} to {_empty}
    loop {kGame::registersGame::*}:
        if loop-value is true:
            set slot {kGame::registersGame::%loop-index%::slot} of {_x} to {kGame::registersGame::%loop-index%::item}
    return {_x}
import:
    org.bukkit.event.inventory.InventoryClickEvent
on script load:
    if yaml value "inventory.name" from kGame_getPath("kGame_Util", "mainInventory") is not set:
        set yaml value "inventory.name" from kGame_getPath("kGame_Util", "mainInventory") to "&9Dostepne gry:"
        set yaml value "inventory.rows" from kGame_getPath("kGame_Util", "mainInventory") to 3
        set yaml value "inventory.empty" from kGame_getPath("kGame_Util", "mainInventory") to "gray stained glass pane named ""&l"""
    kGame_reloadYaml()
command /gry [<text>] [<text>]:
    aliases: games
    trigger:
        if sender has permission "*":
            if arg 1 is not set:
                send "/gry reload &7przeladowywuje konfiguracje yaml"
                if sender is player:
                    send "/gry graj -> &7wyswietla GUI"
                stop
            if arg 1 is "reload":
                if arg 2 is not set:
                    set {_x} to "main"
                    loop {kGame::registersGame::*}:
                        set {_x} to "%{_x}%, %loop-index%"
                    send "&7Masz do wyboru: &6%{_x}%"
                    stop
                if arg 2 is "main":
                    kGame_reloadYaml()
                if arg 2 is "stats" or "statistics":
                    evaluate "set {_b} to kGame_stats_reloadYaml(""stats"")"
                    if {kGame::registersGame::stats} is set:
                        evaluate "set {_b2} to kGame_stats_reloadYaml(""statistics"")"
                    if {_b} is true:
                        send "&aPrzeladowano: &7Stats/mainInventory.yml"
                    else if {_b} is false:
                        send "&cNiepowodzenie: &7Stats/mainInventory.yml"
                    if {_b2} is true:
                        send "&aPrzeladowano: &7Stats/statistics.yml"
                    else if {_b2} is false:
                        send "&cNiepowodzenie: &7Stats/statistics.yml"
                    stop
                if {kGame::registersGame::%arg 2%} is true:
                    evaluate "set {_b} to kGame_%arg 2%_reloadYaml()"
                    if {_b} is true:
                        send "&aPrzeladowano: &7%arg 2%"
                    else:
                        send "&cNiepowodzenie: &7%arg 2%"
                stop
            if arg 1 is "graj":
                if sender is player:
                    open kGame_getInventory(player) to player
            stop
        open kGame_getInventory(player) to player
on InventoryClickEvent:
    set {_top} to event.getWhoClicked().getOpenInventory().getTopInventory()
    if name of {_top} is {kGame::mainInventory::inventory::name}:
        cancel event
        if event.getClickedInventory() is {_top}:
            set {_slot} to event.getRawSlot()
            set {_if} to kGame_getItemFromText({kGame::mainInventory::inventory::item::empty})
            if type of event.getCurrentItem() is type of {_if}:
                stop
            loop {kGame::registersGame::*}:
                loop-value is true
                if {kGame::registersGame::%loop-index%::slot} is {_slot}:
                    set {_execute} to loop-index
            #Poprawienie wielkosci liter, gdyz Funkcja nie dziala.
            loop yaml nodes "inventory" from kGame_getPath("kGame_Util", "mainInventory"):
                if loop-value is {_execute}:
                    set {_execute} to loop-value
            if {_execute} is not set:
                stop
            set {_p} to event.getWhoClicked()
            close {_p}'s inventory
            wait 2 tick
            evaluate "set {_x} to kGame_%{_execute}%_getInventory({_p})"
            open {_x} to {_p}
            stop