# ███╗░░░███╗░█████╗░██████╗░███╗░░░███╗░█████╗░███╗░░██╗░█████╗░░██████╗░███████╗██████╗░
# ████╗░████║██╔══██╗██╔══██╗████╗░████║██╔══██╗████╗░██║██╔══██╗██╔════╝░██╔════╝██╔══██╗
# ██╔████╔██║██║░░██║██████╦╝██╔████╔██║███████║██╔██╗██║███████║██║░░██╗░█████╗░░██████╔╝
# ██║╚██╔╝██║██║░░██║██╔══██╗██║╚██╔╝██║██╔══██║██║╚████║██╔══██║██║░░╚██╗██╔══╝░░██╔══██╗
# ██║░╚═╝░██║╚█████╔╝██████╦╝██║░╚═╝░██║██║░░██║██║░╚███║██║░░██║╚██████╔╝███████╗██║░░██║
# ╚═╝░░░░░╚═╝░╚════╝░╚═════╝░╚═╝░░░░░╚═╝╚═╝░░╚═╝╚═╝░░╚══╝╚═╝░░╚═╝░╚═════╝░╚══════╝╚═╝░░╚═╝

# Witaj w MobManager!
# Chcesz zarządzać mobami i robić walki między nimi, ale wkurza Cię instalowanie modów i długie komendy?
# Nie? No dobra :(
# Ale jeśli kiedyś będziesz chciał, to pozostawiam Ci ten skrypt!
# Jeśli jesteś zainteresowany, to pozwól że wytłumaczę Ci jak działa.
# 1. Co dodaje MobManager?
# Ten skrypt dodaje 3 nowe (domyślnie patyki) zarządzające:
# Atakiem na wybranego moba przez innego wybranego moba,
# równą walką między nimi,
# oraz zarządzaniem ekwipunkiem wybranego moba.
# Dodana została jeszcze komenda /magic <id przedmiotu> <gracz>, która pozwala nadać wybrany magiczny przedmiot
# wybranemu graczowi, bądź sobie.
# 2. Jak używać?
# a) patyk ataku - Patyk ataku pozwala na zaatakowanie jednego moba przez drugiego. Wystarczy tylko, że
# klikniesz lewym przyciskiem myszy na moba który ma atakować, oraz prawym na drugiego który ma być ofiarą.
# b) patyk walki - Patyk walki działa podobnie do poprzedniego, jednak różni się tym, że nie ma w nim ofiary ani
# atakującego. Oba moby ruszają JEDNOCZEŚNIE na siebie. Wystarczy tylko, że klikniesz lewym na pierwszego,
# oraz prawym na druiego.
# c) patyk zarządzania mobami - Patyk różni się od dwóch poprzednich, ponieważ pozwala na zakładanie i zdejmowanie
# zbroji, oraz dawanie i zabieranie przedmiotów do głównej ręki i drugiej ręki. Aby to zrobić, wystarczy, że
# klikniesz prawym przyciskiem myszy jednocześnie kucając.
# Pierwsze 2 patyki mają jednak jedną wadę - Nie możemy robić walk dosłownie wszystkich mobów. Przeważnie nie możemy
# robić walk między dwoma tymi samymi ,,gatunkami", np. między dwoma evokerami, wardenami czy ravagerami. Wyjątkami
# są np. zombie, szkielety czy golemy. Nie możemy także robić niektórych walk innych od siebie gatunków takich,
# które są ze sobą w jakiś sposób połączone, np. evoker i ravager, ponieważ uczestniczą razem w raidach.
# 3. Dodatkowe informacje, zaobserwowane podczas testowania skryptu:
# - W przypadku Wardena, może on walczyć z KAŻDYM mobem. (oprócz innym wardenem rzecz jasna.)
# - Na zbroję moba można zakładać nie tylko zbroje, ale każdy dostępny item, jednak widoczne będą tylko na głowie.
# 4. Dla ciekawskich - Jak działa ,,agrowanie" mobów na siebie? (Ostatni etap)
# Jeśli zastanawiasz się, jak to się dzieje że moby nagle zaczynają walczyć ze sobą? Skrypt na pewną linijkę,
# która sprawia, że wybrany atacker dostaje obrażenia (takie które nic nie zabierają, 0,001 serca), jednak
# te obrażenia, są zarejestrowane jako pochodzące od ofiary, przez co atacker myśli, że ofiara go zaatakowała,
# więc rusza za to ją zabić. Kiedy natomiast już ją uderzy, ofiara za to uderzenie również się zdenerwuje
# i zaczną się bić. W przypadku nie ataku, a walki działa to tak samo jednak OBA moby dostają od siebie 0,001 obrażeń.
# Konfiguracja:
options:

    prefix: &3Serwer &e>>

    commandUsage: &cUżycie komendy: /magic <id przedmiotu> <*gracz*>
    commandPermission: serwer.magic
    commandPermissionMessage: &cNie masz permisji!
    commandDescription: Nadaje wybrany magiczny przedmiot wybranemu graczowi lub sobie.
    commandSuccessOther: &aPomyślnie nadałeś magiczny item graczowi &2(G)&a!
    commandSuccessYour: &aPomyślnie nadałeś sobie magiczny item!
    commandOffline: &cNie ma takiego gracza online!
    commandUnknownType: &cRodzaj &4(R) &cnie został rozpoznany!

    itemAttack: stick
    itemAttackId: Atak
    itemAttackName: &1Patyk ataku
    itemAttackLore: &bKliknij lewym, aby zaznaczyć atakującego!%nl%&9Kliknij prawym, aby zaznaczyć ofiarę!

    itemFight: stick
    itemFightId: Walka
    itemFightName: &bPatyk walki
    itemFightLore: &bKliknij lewym, aby zaznaczyć pierwszego fightera!%nl%&9Kliknij prawym, aby zaznaczyć drugiego fightera!

    itemModify: stick
    itemModifyId: Ekwipunek
    itemModifyName: &aPatyk zarządzania mobami
    itemModifyLore: &9Kliknij prawym kucając, aby edytować ekwipunek potwora!

    firstAttackSuccess: &aPomyślnie zaznaczyłeś atakującego.
    secondAttackSuccess: &aPomyślnie zaznaczyłeś ofiarę, rozpoczynając atak!

    firstFightSuccess: &aPomyślnie zaznaczyłeś pierwszego fightera.
    secondFightSuccess: &aPomyślnie zaznaczyłeś drugiego fightera, rozpoczynając walkę!

# Skrypt - jeśli nie umiesz pisać skryptów w języku Skript, lepiej nie edytuj nic poniżej.

on damage of entity:
    attacker's tool is {@itemAttack} named "{@itemAttackName}" with lore "{@itemAttackLore}":
        cancel event
        set {attackone::%attacker%} to uuid of victim
        send "{@prefix} {@firstAttackSuccess}" to the attacker
    attacker's tool is {@itemFight} named "{@itemFightName}" with lore "{@itemFightLore}":
        cancel event
        set {fightone::%attacker%} to uuid of victim
        send "{@prefix} {@firstFightSuccess}" to the attacker

on rightclick on entity:
    player's tool is {@itemAttack} named "{@itemAttackName}" with lore "{@itemAttackLore}":
        if {attackone::%player%} is set:
            send "{@prefix} {@secondAttackSuccess}" to the player
            set {_at1} to {attackone::%player%} parsed as entity
            make event-entity damage {_at1} by 0.01
    player's tool is {@itemFight} named "{@itemFightName}" with lore "{@itemFightLore}":
        if {fightone::%player%} is set:
            send "{@prefix} {@secondFightSuccess}" to the player
            set {_fi1} to {fightone::%player%} parsed as entity
            make event-entity damage {_fi1} by 0.01
            make {_fi1} damage event-entity by 0.01
    player's tool is {@itemModify} named "{@itemModifyName}" with lore "{@itemModifyLore}":
        player is sneaking
        set {_} to chest inventory with 3 rows named "&3Eq moba &a%uuid of event-entity%"
        set {_n} to -1
        loop 27 times:
            add 1 to {_n}
            set slot {_n} of {_} to gray stained glass pane
        set slot 10 of {_} to helmet of event-entity
        set slot 11 of {_} to chestplate of event-entity
        set slot 12 of {_} to leggings of event-entity
        set slot 13 of {_} to boots of event-entity
        set slot 14 of {_} to tool of event-entity
        set slot 15 of {_} to off hand tool of event-entity
        open {_} to player

on inventory click:
    name of event-inventory contains "&3Eq moba &a"
    event-inventory is not player's inventory
    clicked slot is not 10 or 11 or 12 or 13 or 14 or 15:
        cancel event

on inventory close:
    name of event-inventory contains "&3Eq moba &a"
    event-inventory is not player's inventory
    set {_n} to name of event-inventory
    replace all "&3Eq moba &a" in {_n} with ""
    set {_n} to {_n} parsed as entity
    set helmet of {_n} to slot 10 of event-inventory
    set chestplate of {_n} to slot 11 of event-inventory
    set leggings of {_n} to slot 12 of event-inventory
    set boots of {_n} to slot 13 of event-inventory
    set tool of {_n} to slot 14 of event-inventory
    set off hand tool of {_n} to slot 15 of event-inventory

command magic <text> [<offline player=%sender%>]:
    permission: {@commandPermission}
    permission message: {@prefix} {@commandPermissionMessage}
    description: {@commandDescription}
    usage: {@prefix} {@commandUsage}
    trigger:
        if arg-1 is not "{@itemAttackId}" or "{@itemFightId}" or "{@itemModifyId}":
            set {_commandUnknownType} to "{@commandUnknownType}"
            replace all "(R)" in {_commandUnknownType} with arg-1
            send "{@prefix} %{_commandUnknownType}%" to the sender
            stop
        if arg-2 is not sender:
            if arg-2 is online:
                set {_arg2} to arg-2
                set {_arg2} to {_arg2} parsed as player
                set {_commandSuccessOther} to "{@commandSuccessOther}"
                replace all "(P)" in {_commandSuccessOther} with "%arg-2%"
                if arg-1 is "{@itemAttackId}":
                    give 1 of {@itemAttack} named "{@itemAttackName}" with lore "{@itemAttackLore}" to {_arg2}
                    send "{@prefix} %{_commandSuccessOther}%" to the sender
                if arg-1 is "{@itemFightId}":
                    give 1 of {@itemFight} named "{@itemFightName}" with lore "{@itemFightLore}" to {_arg2}
                    send "{@prefix} %{_commandSuccessOther}%" to the sender
                if arg-1 is "{@itemModifyId}":
                    give 1 of {@itemModify} named "{@itemModifyName}" with lore "{@itemModifyLore}" to {_arg2}
                    send "{@prefix} %{_commandSuccessOther}%" to the sender
                stop
            else:
                send "{@prefix} {@commandOffline}" to the sender
        else:
            if arg-1 is "{@itemAttackId}":
                give 1 of {@itemAttack} named "{@itemAttackName}" with lore "{@itemAttackLore}" to player
                send "{@prefix} {@commandSuccessYour}" to the sender
            if arg-1 is "{@itemFightId}":
                give 1 of {@itemFight} named "{@itemFightName}" with lore "{@itemFightLore}" to player
                send "{@prefix} {@commandSuccessYour}" to the sender
            if arg-1 is "{@itemModifyId}":
                give {@itemModify} named "{@itemModifyName}" with lore "{@itemModifyLore}" to player
                send "{@prefix} {@commandSuccessYour}" to the sender
            stop

on tab complete of "/magic":
    set tab completion for position 1 to "{@itemAttackId}" and "{@itemFightId}" and "{@itemModifyId}"

# # # # # # # # # # # # #
# MobManager 1.0 by TeZetYT #
# # # # # # # # # # # # #