options:
    gameName: clicker
on script load:
    kGame_registerGame("{@gameName}", 22, (1 of stone button named "&6Clicker" with lore "&7Sprawdz ile wycisniesz w 10 sekund"))
    kGame_stats_registerGame("{@gameName}", 13, stone button named "&6Clicker")
    kGame_stats_setLore("{@gameName}", "&fRozegrane gry: &e{played}||&fNajwiekszy Twoj wynik: &e{count}||*top5:{count};&cTop 5 wynikow:*||*top10:{played};&aTop 10 rozegranych gier:*")
on script unload:
    kGame_unregisterGame("{@gameName}")
function kGame_clicker_getInventory(p: player) :: inventory:
    set {_x} to chest with 1 rows named "&9Clicker"
    loop 8 times:
        set slot loop-number of {_x} to gray stained glass pane named "&l"
    set slot 0 of {_x} to stone button named "&7Kliknij, aby rozpoczac." with lore "&6Kliknij raz i zacznie sie odliczanie."
    set slot 8 of {_x} to iron door named "&6Powrot do gier"
    return {_x}
on inventory click:
    if name of player's current inventory is "&9Clicker":
        if index of clicked slot is smaller than 0:
            stop
        cancel event
        if index of clicked slot is 0:
            if name of slot 0 of player's current inventory contains "Kliknij":
                kGame_stats_add("{@gameName}", player)
                set {kGame::clicker::%player%::count} to 0
                set slot 0 of player's current inventory to stone button named "&7Odliczanie..." with lore "&7Pozostalo: &a10"
                loop 10 times:
                    if name of player's current inventory is not "&9Clicker":
                        clear {kGame::clicker::%player%::count}
                        stop
                    wait 1 second
                    set {_x} to join (uncoloured lore of slot 0 of player's current inventory) with nl
                    replace all "Pozostalo: " with "" in {_x}
                    set {_x} to {_x} parsed as integer
                    set slot 0 of player's current inventory to stone button named "&7Odliczanie..." with lore "&7Pozostalo: &a%{_x} - 1%"
                set slot 0 of player's current inventory to stone button named "&7Koniec." with lore "&6Twoj wynik: &4%{kGame::clicker::%player%::count}%"
                kGame_stats_update("{@gameName}", player, "count", {kGame::clicker::%player%::count}, "larger than")
                wait 3 seconds
                clear {kGame::clicker::%player%::count}
                if name of player's current inventory is not "&9Clicker":
                    stop
                set slot 0 of player's current inventory to stone button named "&7Kliknij, aby rozpoczac." with lore "&6Kliknij raz i zacznie sie odliczanie."
            if name of slot 0 of player's current inventory is "&7Odliczanie...":
                add 1 to {kGame::clicker::%player%::count}
        else:
            if {kGame::clicker::%player%::count} is set:
                stop
            if index of clicked slot is 8:
                close player's inventory
                wait 2 tick
                open kGame_getInventory(player) to player
                stop