options:
# +--------------------------------------------------------------+
# UltimateBank by Bealang
# Wersja V1.0
# W razię błędu/propozycji napisz do mnie na discorda
# Wszystkie dostepne komendy:
#    /bank - menu główne banku
#    /bank zaloz - zakłada konto bankowe
#    /bank usun - usuwa konto bankowe
#    /wplac <ilosc> - wplaca pieniadze do banku
#    /wyplac <ilosc> - wyplaca pieniadze z banku
#    /przelew <ilosc> - przelewa pieniądze danemu graczowi
# Bealang#0488
    # Domyślna kwota do wpłacenia/wyplacenia w banku.
    default-price: 500
# +--------------------------------------------------------------+
# Kod edytuj na własną odpowiedzialność!
# +--------------------------------------------------------------+
variables:
    {bank::wplacone::%player%} = 0
    {bank::zalozoneKonto::%player%} = false
    {bank::id::%player%} = 0
command /bank [<text>]:
    trigger:
        if arg 1 is not set:
            if {bank::zalozoneKonto::%player%} is true:
                set {_bankgui} to chest inventory with 3 row named "&8» &2&lTwoje konto bankowe"
                set slot 18 of {_bankgui} to enchanted book named "&6&lCo to?" with lore "Witaj w banku! Wplacaj i wyplacaj swoje pieniadze! %nl%Trzymaj pieniadze w bezpiecznym miejscu, Nie bojac sie ze je stracisz! %nl%Dostepne komendy: %nl%&f/wplac (kwota) &8» &6Wplac podana kwote do banku! %nl%&f/wyplac (kwota) &8» &6Wyplac podana kwote z banku! %nl%"                                
                set slot 11 of {_bankgui} to diamond named " &6Informacje o koncie:&r" with lore " &aWlasciciel konta: &f%player% %nl%&a ID konta: &f##%{bank::id::%player%}% %nl% &aKonto zostalo utworzone: &f%{bank::datazalozenia::%player%}% &r%nl% %nl% &aObecnie posiadasz &f%{bank::wplacone::%player%}%$ &aw banku. %nl%"           
                set slot 13 of {_bankgui} to gold ingot named "&aKliknij, by wplacic &f{@default-price}$"
                set slot 14 of {_bankgui} to gold ingot named "&cKliknij, by wyplacic &f{@default-price}$"
                set slot 26 of {_bankgui} to arrow named "&c&lKliknij, by usunac konto bankowe" with lore "&cUsuwajac konto bankowe %nl%&czostanie przywrocone ci &f%{bank::wplacone::%player%}%$"
                open {_bankgui} for player
            else:
                set {_bankgui2} to chest inventory with 3 row named "&8» &cZaloz konto!"
                set slot 18 of {_bankgui2} to enchanted book named "&6&lCo to?" with lore "&fWplacaj i wyplacaj swoje pieniadze! %nl%&fTrzymaj pieniadze w bezpiecznym miejscu, Nie bojac sie ze je stracisz! %nl%Dostepne komendy: %nl%&f/wplac (kwota) &8» &6Wplac podana kwote do banku! %nl%&f/wyplac (kwota) &8» &6Wyplac podana kwote z banku! %nl%"                                
                set slot 11 of {_bankgui2} to barrier named " &6Informacje o koncie:&r" with lore "&cNie posiadasz konta bankowego! %nl%&cZaloz konto komenda &f/bank zaloz"           
                set slot 13 of {_bankgui2} to barrier named " " with lore "&cNie posiadasz konta bankowego! %nl%&cZaloz konto komenda &f/bank zaloz"
                set slot 14 of {_bankgui2} to barrier named " " with lore "&cNie posiadasz konta bankowego! %nl%&cZaloz konto komenda &f/bank zaloz"
                open {_bankgui2} for player
        if arg 1 is "zaloz":
            if {bank::zalozoneKonto::%player%} = false:
                set {bank::zalozoneKonto::%player%} to true
                set {bank::id::%player%} to {bank::id::ilosc}
                add 1 to {bank::id::ilosc}
                set {bank::id::%player%} to {bank::id::ilosc}
                send "&8» &aPomyslnie stworzono konto bankowe!"
                set {bank::datazalozenia::%player%} to now
                execute player command "bank"
            else:
                send "&8» &cJuz posiadasz konto w banku!"
        if arg 1 is "usun":
            if {bank::zalozoneKonto::%player%} is true:
                set {bank::zalozoneKonto::%player%} to false
                send "&8» &aUsunales konto i przyznano ci &f%{bank::wplacone::%player%}%$"
                send title "&a+%{bank::wplacone::%player%}%$"
                add {bank::wplacone::%player%} to player's balance
                wait 1 second
                set {bank::wplacone::%player%} to 0
            else:
                send "&8» &cNie masz konta bankowego!"
on inventory click:
        event-inventory is not player's inventory
        if name of event-inventory is "&8» &2&lTwoje konto bankowe":
                cancel event
                if clicked slot is 11:
                        send "&8» &aObecnie posiadasz &f%{bank::wplacone::%player%}%$"
                if clicked slot is 13:
                        close player's inventory
                        execute player command "wplac {@default-price}"
                if clicked slot is 14:
                        close player's inventory
                        execute player command "wyplac {@default-price}"
                if clicked slot is 26:
                        close player's inventory
                        execute player command "bank usun"
        if name of event-inventory is "&8» &cZaloz konto!":
                cancel event
command /wplac [<number>]:
    usage: &8» &cNieprawidlowa liczba!
    aliases: deposit
    trigger:
        if arg 1 is set:
            if {bank::zalozoneKonto::%player%} is true:
                if arg 1 <= player's balance:
                    remove arg 1 from player's balance
                    add arg 1 to {bank::wplacone::%player%}
                    send "&8» &aPomyslnie wplacono &f%arg 1%$ &ado banku."
                else:
                    send "&8» &cNie masz wystarczajaco pieniedzy! Posiadasz obecnie &f%player's balance% &cprzy sobie"
            else:
                send "&8» &cZaloz konto komenda &f/bank zaloz&c!"
command /wyplac [<number>]:
    usage: &8» &cNieprawidlowa liczba!
    aliases: withdraw
    trigger:
        if arg 1 is set:
            if {bank::zalozoneKonto::%player%} is true:
                if arg 1 <= {bank::wplacone::%player%}:
                    remove arg 1 from {bank::wplacone::%player%}
                    add arg 1 to player's balance
                    send "&8» &aPomyslnie wyplacono &f%arg 1%$ &az banku."
                else:
                    send "&8» &cNie masz wystarczajaco pieniedzy! Posiadasz obecnie &f%{bank::wplacone::%player%}%$ &cw banku"
            else:
                send "&8» &cZaloz konto komenda &f/bank zaloz&c!"
command /przelew [<player>] [<number>]:
    usage: &8» &cNieprawidlowa liczba/gracz!
    trigger:
        if arg 2 is set:
            if {bank::zalozoneKonto::%player%} is true:
                if arg 1 is not executor:
                    if arg 2 <= {bank::wplacone::%player%}:
                        remove arg 2 from {bank::wplacone::%player%}
                        add arg 2 to {bank::wplacone::%arg 1%}
                        send "&8» &aPrzelales &f%arg 2%$ &agraczowi &f%arg 1%&a."
                        send "&8» &aObecnie posiadasz: &f%{bank::wplacone::%player%}%$"
                        send title "&c- %arg 2%$"
                        send "&8» &f%player% &aprzelal ci &f%arg 2%$&a!" to arg 1
                        send "&8» &aObecnie posiadasz: &f%{bank::wplacone::%arg 1%}%$" to arg 1
                        send title "&a+ %arg 2%$" to arg 1
                    else:
                        send "&8» &cNie masz wystarczajaco pieniedzy! Posiadasz obecnie &f%{bank::wplacone::%player%}%$ &cw banku"
                else:
                    send "&8» &cNie mozesz wysylac pieniedzy do siebie!"
            else:
                send "&8» &cZaloz konto komenda &f/bank zaloz&c!"