options:
#     Permisja do edytowania tabliczki
    permission-to-edit: SignEdit.edit
#     Wiadomość jeżeli gracz nie ma permisji.
    no-permission-to-edit-msg: "&cNie masz permisji do edytowania tabliczek!"
#     Czy każdy może edytować każdą tabliczkę czy ma się wyświetlić GUI do wyboru
#     "Czy chcesz aby tabliczkę mógł edytować każdy czy tylko ty"
#     (true/false)
    private-sign: true
    
#     1. - Nazwa gui
#     2. - Przycisk "Każdy"
#     3. - Przycisk "Tylko ja"
    private-Sign-GUI-name: &8Kto może edytować tą tabliczke?
    private-Sign-Button-Yes: &a&lKażdy
    private-Sign-Button-No: &c&lTylko ja
    
#     Wiadomość o wyłączeniu edytowania przez użytkownika
#     Dostępne symbple zastepcze:
#      - %{signCreatePLR::%{_}%}% - Zwraca właściciela tabliczki
#      - %player% - zwraca gracza który klikną na tabliczkę.
#     (Oraz wszystkie inne symbole zastępcze które posiada skript)
    dont-change-sign: "&cEdytowanie tej tabliczki zostało wyłączone przez %{signCreatePLR::%{_}%}%"
    

#----------------------------------------------
#--------------RESET-NA-TESTOWANIE-------------
#---------PEWNIE-NIGDY-TEJ-CZĘŚCI-KODU---------
#------------------NIE-UŻYJESZ-----------------
command /resetsign:
    permission: *
    trigger:
        delete {SignPrivateList::*}
        delete {signCreate::*}
#-----------------------------------------------------------------------------
#---------------------------KODU-NIE-EDYTOWAĆ---------------------------------
#---------------------MOŻE-ŻE-WIESZ-CO-CHCESZ-ZMIENIĆ-------------------------
#-----------------------------------------------------------------------------
on rightclick on sign:
    if player has permission "{@permission-to-edit}":
        set {_} to clicked block
        if {@private-sign} is true:
            loop {SignPrivateList::*}:
                if "%loop-value%" is "%{_}%":
                    if player is not {signCreatePLR::%{_}%}:
                        send {@dont-change-sign}
                        stop
        open sign gui to player with "%line 1 of clicked block%", "%line 2 of clicked block%", "%line 3 of clicked block%", "%line 4 of clicked block%":
            set line 1 of {_} to 1st element out of lines
            set line 2 of {_} to 2nd element out of lines
            set line 3 of {_} to 3rd element out of lines
            set line 4 of {_} to 4th element out of lines
    else:
        send {@no-permission-to-edit-msg}
        
on break of sign:
    set {_} to event-block
    if {@private-sign} is true:
        loop {SignPrivateList::*}:
            if "%loop-value%" is "%{_}%":
                delete {SignPrivateList::%loop-index%}
                delete {signCreatePLR::%{_}%}
                stop
        
on sign change:
    close player's inventory
    set {_} to event-block
    if {@private-sign} is true:
        open chest inventory with 1 rows named "{@private-Sign-GUI-name}" to player
        loop 9 times:
            set slot (9 - loop-value) of player's current inventory to gray stained glass pane named ""
        set slot 3 of player's current inventory to lime concrete named "{@private-Sign-Button-Yes}" 
        set slot 5 of player's current inventory to red concrete named "{@private-Sign-Button-No}" 
        set {signCreate::%player%} to {_}
        set {signCreatePLR::%{_}%} to player
            
            
on inventory click:
    event-inventory is not player's inventory
    if name of event-inventory is "{@private-Sign-GUI-name}":
        cancel event
        if clicked slot is 3:
            close player's inventory
            delete {signCreate::%player%}
        if clicked slot is 5:
            close player's inventory
            add {signCreate::%player%} to {SignPrivateList::*}
            delete {signCreate::%player%}