variables:
	{gildie::%player%::status} = false

options:
#===============Itemy na gildie=====================#
	guild-items: 64 obsidian and 5 ender pearl and 16 diamond block and 8 golden apple and 16 iron block
#==============Czat ==========================================#
	chat: &6{GUILD} &7» {RANK}&7{PLAYER}&7: &f{MESSAGE}
#======================Dlugosc nazwy, tagu gildii===================================#
	nazwa.max: 20 #Max zanków w zakladaniu gildii
	nazwa.min: 6 #Min znaków w zakladaniu gildii
	tag.min: 2 #Min znakow w Tagu gildii
	tag.max: 4 #Max znakow w Tagu gildii
#===================
# command /g pomoc #
command /g pomoc:
	trigger:
		send "&2Komendy Gracza:"
		send "&7» &6/dolacz <tag> &7- &7dolacza do gildii"
		send "&7» &6/opusc <tag> &7- &7opuszczasz gildie"
		send "&7» &6/dom <tag> &7- &7teleportuje do domu gildii"
		send "&7» &6/gildia <tag> &7- &7informacje o gildii"
		send "&2Zarzadzanie Gildia:"
		send "&7» &6/zaloz <tag> <nazwa> &7- &7zaklada gildie"
		send "&7» &6/rozwiaz <tag> &7- &7rozwiazuje gildie"
		send "&7» &6/zapros <gracz> &7- &7zaprasza gracza do gildii"
		send "&7» &6/wyrzuc <gracz> &7- &7wyrzuca gracza z gildii"
		send "&7» &6/lider <gracz> &7- &7zmienia lidera gildii"
		send "&7» &6/zastepca <gracz> &7- &7zmienia zastepce gildii"
		send "&7» &6/ustawdom &7- &7ustawia dom gildii"
		send "&7» &6/pvp &7- &7zmienia pvp w gildii"
		send "&7» &6/opis <opis> &7- &7zmienia opis gildii"
		stop

# command /lider #
command /lider [<text>]:
	trigger:
		if arg 1 is not set:
			send "&7» &7Poprawne uzycie: &6/lider <gracz>"
			stop
		if arg 1 is set:
			if {gildie::%player%::status} is false:
				send "&7» &cNie posiadasz gildii!"
				stop
			if {gildie::gildia::%{gildie::%player%::tag}%::lider} is not "%player%":
				send "&7» &cNie jestes liderem gildii!"
				stop
			if arg 1 is "%{gildie::gildia::%{gildie::%player%::tag}%::lider} parsed as player%":
				send "&7» &cNie mozesz dac sobie lidera gildii!"
				stop
			if arg 1 parsed as player is online:
				loop {gildie::gildia::%{gildie::%player%::tag}%::czlonkowie::*}:
					if loop-value is "%arg 1 parsed as player%":
						set {gildie::gildia::%{gildie::%player%::tag}%::lider} to "%arg 1 parsed as player%"
						send "&7» &7Zmieniles lidera gildii na &6%arg 1 parsed as player%&7."
						send "&7» &7Zostales nowym liderem gildii." to arg 1 parsed as player
						stop
				send "&7» &cGracz o podanym nicku nie nalezy do twojej gildii!"
				stop
			else:
				send "&7» &cGracz o podanym nicku jest offline!"
				stop

# command /zastepca #
command /zastepca [<text>]:
	trigger:
		if arg 1 is not set:
			send "&7» &7Poprawne uzycie: &6/zastepca <gracz>"
			stop
		if arg 1 is set:
			if {gildie::%player%::status} is false:
				send "&7» &cNie posiadasz gildii!"
				stop
			if {gildie::gildia::%{gildie::%player%::tag}%::lider} is not "%player%":
				send "&7» &cNie jestes liderem gildii!"
				stop
			if arg 1 parsed as player is online:
				loop {gildie::gildia::%{gildie::%player%::tag}%::czlonkowie::*}:
					if loop-value is "%arg 1 parsed as player%":
						set {gildie::gildia::%{gildie::%player%::tag}%::zastepca} to "%arg 1 parsed as player%"
						send "&7» &7Zmieniles zastepce gildii na &6%arg 1 parsed as player%&7."
						send "&7» &7Zostales nowym zastepca gildii." to arg 1 parsed as player
						stop
				send "&7» &cGracz o podanym nicku nie nalezy do twojej gildii!"
				stop
			else:
				send "&7» &cGracz o podanym nicku jest offline!"
				stop

# command /wyrzuc #
command /wyrzuc [<text>]:
	trigger:
		if arg 1 is not set:
			send "&7» &7Poprawne uzycie: &6/wyrzuc <gracz>"
			stop
		if {gildie::%player%::status} is false:
			send "&7» &cNie posiadasz gildii!"
			stop
		if {gildie::gildia::%{gildie::%player%::tag}%::lider} is not "%player%":
			send "&7» &cNie jestes liderem gildii!"
			stop
		if arg 1 parsed as player is player:
			send "&7» &cNie mozesz wyrzucic samego siebie!"
			stop
		if arg 1 parsed as player is online:
			loop {gildie::gildia::%{gildie::%player%::tag}%::czlonkowie::*}:
				if loop-value is "%arg 1 parsed as player%":
					set {gildie::%arg 1 parsed as player%::status} to false
					remove "%arg 1 parsed as player%" from {gildie::gildia::%{gildie::%player%::tag}%::czlonkowie::*}
					delete {gildie::%arg 1 parsed as player%::tag}
					stop
			send "&7» &cGracz o podanym nicku nie nalezy do twojej gildii!"
			stop
		else:
			send "&7» &cGracz o podanym nicku jest offline!"
			stop

# command /opis #
command /opis [<text>]:
	trigger:
		if {gildie::%player%::status} is false:
			send "&7» &cNie posiadasz gildii!"
			stop
		if {gildie::gildia::%{gildie::%player%::tag}%::lider} is not "%player%":
			send "&7» &cNie jestes liderem gildii!"
			stop
		if arg 1 is not set:
			send "&7» Poprawne uzycie: &6/opis <opis>"
			stop

		set {gildie::gildia::%{gildie::%player%::tag}%::opis} to "%arg 1%"
		send "&7» &7Opis gildii zostal zmieniony na: &6%arg 1%&7."
		stop

# command /dom #
command /dom [<text>]:
	trigger:
		if arg 1 is not set:
			if {gildie::%player%::status} is false:
				send "&7» &cNie posiadasz gildii!"
				stop
			set {_loc} to "%x-location of player%, %y-location of player%, %z-location of player%"
			send "&7» &7Teleportacja do domu gildii zostala rozpoczeta, poczekaj &610 sekund&7."
			loop 10 times:
				if {_loc} is not "%x-location of player%, %y-location of player%, %z-location of player%":
					send "&7» &cPoruszyles sie, teleportacja zostala anulowana!"
					stop
				wait 1 second
			send "&7» &7Przeteleportowano do domu gildii."
			teleport player to {gildie::gildia::%{gildie::%player%::tag}%::dom}
			stop
		if arg 1 is set:
			if player has permission "gildie.admin.dom":
				if {gildie::gildia::%arg 1%::tag} is not set:
					send "&7» &cGildia o podanym tagu nie istnieje!"
					stop
				send "&7» &7Przeteleportowano do domu gildii &6%{gildie::gildia::%arg 1%::tag}% &6%{gildie::gildia::%arg 1%::nazwa}%&7."
				teleport player to {gildie::gildia::%arg 1%::dom}
				stop

# command /ustawdom #
command /ustawdom:
	trigger:
		if {gildie::%player%::status} is false:
			send "&7» &cNie posiadasz gildii!"
			stop
		if {gildie::gildia::%{gildie::%player%::tag}%::lider} is not "%player%":
			send "&7» &cNie jestes liderem gildii!"
			stop
		set {_region} to Region.at{location of player};
		if {_region} is not set:
			send "&7» &cDom gildii mozesz ustawic tylko na terenie gildii!"
			stop
		if {_region} is set:
			if {_region} is "%{gildie::%player%::tag}%":
				set {gildie::gildia::%{gildie::%player%::tag}%::dom} to location of player
				send "&7» &7Dom gildii zostal ustawiony."
				stop
			else:
				send "&7» &cDom gildii mozesz ustawic tylko na terenie gildii!"
				stop
		stop

# command /zaloz #
command /zaloz [<text>] [<text>]:
	trigger:
		if {gildie::%player%::status} is true:
			send "&7» &cJestes aktualnie w gildii!"
			stop
		if arg 1 is not set:
			send "&7» &7Poprawne uzycie: &6/zaloz <tag> <nazwa>"
			stop
		if arg 2 is not set:
			send "&7» &7Poprawne uzycie: &6/zaloz <tag> <nazwa>"
			stop
		if length of arg 1 is less than {@tag.min}:
			send "&7» &cPodany tag gildii jest za krotki!"
			stop
		if length of arg 1 is greater than {@tag.max}:
			send "&7» &cPodany tag gildii jest zbyt dlugi!"
			stop
		if length of arg 2 is less than {@nazwa.min}:
			send "&7» &cPodana nazwa gildii jest za krotka!"
			stop
		if length of arg 2 is greater than {@nazwa.max}:
			send "&7» &cPodana nazwa gildii jest zbyt dluga!"
			stop
		if {gildie::gildia::%arg 1%::tag} is set:
			send "&7» &cGildia o podanym tagu juz istnieje!"
			stop
		if {gildie::gildia::%arg 1%::nazwa} is set:
			send "&7» &cGildia o podanej nazwie juz istnieje!"
			stop
		if player doesn't have {@guild-items}:
			send "&7» &cNie posiadasz przedmiotow aby zalozyc gildie!"
			send "&7» &cAby zalozyc gildie potrzeba: &7%{guild-items-text}%&c."
			stop
		remove {@guild-items} from player

		set {gildie::%player%::status} to true
		set {gildie::%player%::tag} to "%arg 1%"

		set {gildie::gildia::%arg 1%::tag} to "%arg 1%"
		set {gildie::gildia::%arg 1%::nazwa} to "%arg 2%"
		set {gildie::gildia::%arg 1%::opis} to "Domyslny opis gildii..."
		set {gildie::gildia::%arg 1%::lider} to "%player%"
		set {gildie::gildia::%arg 1%::zastepca} to "Brak danych"
		set {gildie::gildia::%arg 1%::pvp} to false
		set {gildie::gildia::%arg 1%::dom} to location of player
		add "%player%" to {gildie::gildia::%arg 1%::czlonkowie::*}

		"%arg 1%".Region.selectLS{location of player, 50};

		set {_id} to Region.at{location of player};

		add {_id} to {cuboids::*}

		set {cuboids::%{_id}%::location} to {gildie::gildia::%arg 1%::dom}

		set block at player to dragon egg

		broadcast "&7» &7Gracz &6%player% &7zalozyl gildie o tagu &6%arg 1% &7oraz nazwie &6%arg 2%&7."
		stop

# command /opusc #
command /opusc:
	trigger:
		if {gildie::%player%::status} is false:
			send "&7» &cNie posiadasz gildii!"
			stop
		if {gildie::gildia::%{gildie::%player%::tag}%::lider} is "%player%":
			send "&7» &cNie mozesz opuscic gildii bedac jej liderem!"
			stop

		broadcast "&7» &7Gracz &6%player% &7opuscil gildie o tagu &6%{gildie::gildia::%{gildie::%player%::tag}%::tag}% oraz nazwie &6%{gildie::gildia::%{gildie::%player%::tag}%::nazwa}%&7."

		set {gildie::%player%::status} to false
		remove "%player%" from {gildie::gildia::%{gildie::%player%::tag}%::czlonkowie::*}
		delete {gildie::%player%::tag}
		stop

# command /zapros #
command /zapros [<text>]:
	trigger:
		if {gildie::%player%::status} is false:
			send "&7» &cNie posiadasz gildii!"
			stop
		if arg 1 is not set:
			send "&7» &7Poprawne uzycie: &6/zapros <gracz>"
			stop
		if {gildie::gildia::%{gildie::%player%::tag}%::lider} is not "%player%":
			send "&7» &cNie jestes liderem gildii!"
			stop
		if arg 1 parsed as player is online:
			if {gildie::%arg 1 parsed as player%::tag} is set:
				send "&7» &cGracz o podanym nicku posiada gildie!"
				stop
			if {gildie::%arg 1 parsed as player%::zaproszenie::%{gildie::%player%::tag}%} is not set:
				set {gildie::%arg 1 parsed as player%::zaproszenie::%{gildie::%player%::tag}%} to true
				send "&7» &7Zaprosiles gracza &6%arg 1 parsed as player% &7do gildii!"
				send "&7» &7Zostales zaproszony do gildii &6%{gildie::gildia::%{gildie::%player%::tag}%::tag}% %{gildie::gildia::%{gildie::%player%::tag}%::nazwa}% &7przez gracza &6%player%&7." to arg 1 parsed as player
				send "&7» &7Aby do niej dolaczyl wpisz: &6/dolacz %{gildie::gildia::%{gildie::%player%::tag}%::tag}%&7." to arg 1 parsed as player
				stop
			else:
				if {gildie::%arg 1 parsed as player%::zaproszenie::%{gildie::%player%::tag}%} is true:
					set {gildie::%arg 1 parsed as player%::zaproszenie::%{gildie::%player%::tag}%} to false
					send "&7» &7Cofnales zaproszenie gracza &6%arg 1 parsed as player% &7do gildii!"
					send "&7» &7Gracz &6%player% &7cofnal twoje zaproszenie do gildii &6%{gildie::gildia::%{gildie::%player%::tag}%::tag}% %{gildie::gildia::%{gildie::%player%::tag}%::nazwa}%&7." to arg 1 parsed as player
					stop
				else:
					set {gildie::%arg 1 parsed as player%::zaproszenie::%{gildie::%player%::tag}%} to true
					send "&7» &7Zaprosiles gracza &6%arg 1 parsed as player% &7do gildii!"
					send "&7» &7Zostales zaproszony do gildii &6%{gildie::gildia::%{gildie::%player%::tag}%::tag}% %{gildie::gildia::%{gildie::%player%::tag}%::nazwa}% &7przez gracza &6%player%&7." to arg 1 parsed as player
					send "&7» &7Aby do niej dolaczyl wpisz: &6/dolacz %{gildie::gildia::%{gildie::%player%::tag}%::tag}%&7." to arg 1 parsed as player 
					stop
		else:
			send "&7» &cGracz o podanym nicku jest offline!"
			stop

# command /dolacz #
command /dolacz [<text>]:
	trigger:
		if arg 1 is not set:
			send "&7» &7Poprawne uzycie: &6/dolacz <tag>"
			stop
		if {gildie::%player%::zaproszenie::%arg 1%} is not set:
			send "&7» &cNie posiadasz zaproszenia od tej gildii!"
			stop
		if {gildie::%player%::zaproszenie::%arg 1%} is false:
			send "&7» &cNie posiadasz zaproszenia od tej gildii!"
			stop

		#set {_czlonkowie-size} to size of {gildie::gildia::%arg 1%::czlonkowie::*}
		#set {_i} to {_czlonkowie-size}*3.5+30/1.3+3.5 parsed as integer
		#set {_item} to {_i} diamond parsed as itemstack
		#if player has {_item}:
		#	stop

		set {gildie::%player%::status} to true
		set {gildie::%player%::tag} to "%arg 1%"
		delete {gildie::%player%::zaproszenie::%arg 1%}
		add "%player%" to {gildie::gildia::%arg 1%::czlonkowie::*}

		broadcast "&7» &7Gracz &6%player% &7dolaczyl do gildii &6%arg 1% %{gildie::gildia::%arg 1%::nazwa}%&7."
		stop

# command /pvp #
command /pvp:
	trigger:
		if {gildie::%player%::status} is false:
			send "&7» &cNie posiadasz gildii!"
			stop
		if {gildie::gildia::%{gildie::%player%::tag}%::lider} is not "%player%":
			send "&7» &cNie jestes liderem gildii!"
			stop
		if {gildie::gildia::%{gildie::%player%::tag}%::pvp} is true:
			set {gildie::gildia::%{gildie::%player%::tag}%::pvp} to false
			send "&7» &7Pvp w gildii zostalo wylaczone."
			stop
		else:
			set {gildie::gildia::%{gildie::%player%::tag}%::pvp} to true
			send "&7» &7Pvp w gildii zostalo wlaczone."
			stop
# command /gildia #
command /gildia [<text>]:
	trigger:
		if arg 1 is not set:
			if {gildie::%player%::status} is false:
				send "&7» &cNie posiadasz gildii!"
				stop

			set {_tag} to {gildie::gildia::%{gildie::%player%::tag}%::tag}
			set {_nazwa} to {gildie::gildia::%{gildie::%player%::tag}%::nazwa}
			set {_opis} to {gildie::gildia::%{gildie::%player%::tag}%::opis}
			set {_pvp} to {gildie::gildia::%{gildie::%player%::tag}%::pvp}

			set {_lider} to {gildie::gildia::%{gildie::%player%::tag}%::lider}
			set {_zastepca} to {gildie::gildia::%{gildie::%player%::tag}%::zastepca}
			set {_czlonkowie::*} to {gildie::gildia::%{gildie::%player%::tag}%::czlonkowie::*}

			set {_czlonkowie-size} to size of {_czlonkowie::*}

			send "&7&m---------------&r &6GILDIE &r&7&m---------------"
			send " &7» &7Nazwa: &6%{_nazwa}%"
			send " &7» &7Tag: &6%{_tag}%"
			send " &7» &7Opis: &6%{_opis}%"
			send " &7» &7Lider: &6%{_lider}%"
			send " &7» &7Zastepca: &6%{_zastepca}%"
			if {_pvp} is true:
				send " &7» &7Pvp: &6tak"
			else:
				send " &7» &7Pvp: &6nie"
			send " &7» &7Czlonkowie (%{_czlonkowie-size}%): &6%{_czlonkowie::*}%"
			send "&7&m-------------------------------------"
			stop
		if arg 1 is set:
			if {gildie::gildia::%arg 1%::tag} is not set:
				send "&7» &cGildia o podanym tagu nie istnieje!"
				stop

			set {_tag} to {gildie::gildia::%arg 1%::tag}
			set {_nazwa} to {gildie::gildia::%arg 1%::nazwa}
			set {_opis} to {gildie::gildia::%arg 1%::opis}
			set {_pvp} to {gildie::gildia::%arg 1%::pvp}

			set {_lider} to {gildie::gildia::%arg 1%::lider}
			set {_zastepca} to {gildie::gildia::%arg 1%::zastepca}
			set {_czlonkowie::*} to {gildie::gildia::%arg 1%::czlonkowie::*}

			set {_czlonkowie-size} to size of {_czlonkowie::*}

			send "&7&m---------------&r &6GILDIE &r&7&m---------------"
			send " &7» &7Nazwa: &6%{_nazwa}%"
			send " &7» &7Tag: &6%{_tag}%"
			send " &7» &7Opis: &6%{_opis}%"
			send " &7» &7Lider: &6%{_lider}%"
			send " &7» &7Zastepca: &6%{_zastepca}%"
			if {_pvp} is true:
				send " &7» &7Pvp: &6tak"
			else:
				send " &7» &7Pvp: &6nie"
			set {_temp} to ""
			send " &7» &7Czlonkowie (%{_czlonkowie-size}%): &6%{_czlonkowie::*}%"
			send "&7&m-------------------------------------"
			stop

# command /rozwiaz #
command /rozwiaz [<text>]:
	trigger:
		if arg 1 is not set:
			if {gildie::%player%::status} is false:
				send "&7» &cNie posiadasz gildii!"
				stop
			if {gildie::gildia::%{gildie::%player%::tag}%::lider} is not "%player%":
				send "&7» &cNie jestes liderem gildii!"
				stop

			set {_tag} to {gildie::gildia::%{gildie::%player%::tag}%::tag}
			set {_nazwa} to {gildie::gildia::%{gildie::%player%::tag}%::nazwa}
			set {_czlonkowie::*} to {gildie::gildia::%{gildie::%player%::tag}%::czlonkowie::*}

			"%{_tag}%".Region.delete{};

			delete {gildie::gildia::%{gildie::%player%::tag}%::tag}
			delete {gildie::gildia::%{gildie::%player%::tag}%::nazwa}
			delete {gildie::gildia::%{gildie::%player%::tag}%::opis}
			delete {gildie::gildia::%{gildie::%player%::tag}%::pvp}
			delete {gildie::gildia::%{gildie::%player%::tag}%::czlonkowie::*}
			delete {gildie::gildia::%{gildie::%player%::tag}%::lider}
			delete {gildie::gildia::%{gildie::%player%::tag}%::zastepca}

			set block at {gildie::gildia::%{gildie::%player%::tag}%::dom} to air

			delete {gildie::gildia::%{gildie::%player%::tag}%::dom}

			loop {_czlonkowie::*}:
				set {gildie::%loop-value%::status} to false
				delete {gildie::%loop-value%::tag}

			broadcast "&7» &7Gildia o tagu &6%{_tag}% &7i nazwie &6%{_nazwa}% &7zostala rozwiazana przez &6%player%&7."
			stop
		if arg 1 is set:
			if player doesn't have permission "gildie.admin.rozwiaz":
				send "&7» &cNie posiadasz uprawnien do tej komendy!"
				stop
			set {_tag} to {gildie::gildia::%arg 1%::tag}
			if {_tag} is not set:
				send "&7» &cGildia o podanym tagu nie istnieje!"
				stop
			set {_nazwa} to {gildie::gildia::%arg 1%::nazwa}
			set {_czlonkowie::*} to {gildie::gildia::%arg 1%::czlonkowie::*}

			"%{_tag}%".Region.delete{};

			delete {gildie::gildia::%arg 1%::tag}
			delete {gildie::gildia::%arg 1%::nazwa}
			delete {gildie::gildia::%arg 1%::opis}
			delete {gildie::gildia::%arg 1%::pvp}
			delete {gildie::gildia::%arg 1%::czlonkowie::*}
			delete {gildie::gildia::%arg 1%::lider}
			delete {gildie::gildia::%arg 1%::zastepca}

			set block at {gildie::gildia::%arg 1%::dom} to air

			delete {gildie::gildia::%arg 1%::dom}

			loop {_czlonkowie::*}:
				set {gildie::%loop-value%::status} to false
				delete {gildie::%loop-value%::tag}

			broadcast "&7» &7Gildia o tagu &6%{_tag}% &7i nazwie &6%{_nazwa}% &7zostala rozwiazana przez &6%player% (admin)&7."
			stop
on left click:
	if clicked block is dragon egg:
		cancel event
# on right click event #
on right click:
	if clicked block is dragon egg:
		set {_region} to Region.at{location of player};
		if {_region} is not set:
			stop
		if {_region} is set:
			cancel event
			set {_tag} to {gildie::gildia::%{_region}%::tag}
			set {_nazwa} to {gildie::gildia::%{_region}%::nazwa}
			set {_opis} to {gildie::gildia::%{_region}%::opis}
			set {_pvp} to {gildie::gildia::%{_region}%::pvp}

			set {_lider} to {gildie::gildia::%{_region}%::lider}
			set {_zastepca} to {gildie::gildia::%{_region}%::zastepca}
			set {_czlonkowie::*} to {gildie::gildia::%{_region}%::czlonkowie::*}

			set {_czlonkowie-size} to size of {_czlonkowie::*}

			send "&7&m---------------&r &2Gildie &r&7&m---------------"
			send " &7» &7Nazwa: &6%{_nazwa}%"
			send " &7» &7Tag: &6%{_tag}%"
			send " &7» &7Opis: &6%{_opis}%"
			send " &7» &7Lider: &6%{_lider}%"
			send " &7» &7Zastepca: &6%{_zastepca}%"
			if {_pvp} is true:
				send " &7» &7Pvp: &6tak"
			else:
				send " &7» &7Pvp: &6nie"
			set {_temp} to ""
			send " &7» &7Czlonkowie (%{_czlonkowie-size}%): &6%{_czlonkowie::*}%"
			send "&7&m-------------------------------------"
			stop

# on explode event #
on explode:
	set {_region} to Region.at{event-location};
	if {_region} is not set:
		stop		
	set {gildie::gildia::%{_region}%::explode} to 60
	loop {gildie::gildia::%{_region}%::czlonkowie::*}:
		send "&7» &cNa terenie twojej gildii wybuchlo tnt, nie mozesz na nim budowac przez &760 sekund&c." to loop-value parsed as player
	while {gildie::gildia::%{_region}%::explode} is not 0:
		wait 1 second
		remove 1 from {gildie::gildia::%{_region}%::explode}
	stop

# on place event #
on place:
	set {_region} to Region.at{location of player};
	if {_region} is not set:
		stop
	if {_region} is set:
		if {_region} is "%{gildie::%player%::tag}%":
			if {gildie::gildia::%{gildie::%player%::tag}%::explode} is greater than 0:
				send "&7» &cNa terenie gildii wybuchlo tnt, nie mozesz na nim budowac jeszcze przez &7%{gildie::gildia::%{gildie::%player%::tag}%::explode}% sekund&c."
				cancel event
			stop
		cancel event
		send "&7» &cNie mozesz klasc blokow na terenie innej gildii!"
		stop

# on break event #
on break:
	set {_region} to Region.at{location of player};
	if {_region} is not set:
		stop
	if {_region} is set:
		if {_region} is "%{gildie::%player%::tag}%":
			stop
		cancel event
		send "&7» &cNie mozesz niszczyc blokow na terenie innej gildii!"
		stop

# on damage event#
on damage:
	if victim is player:
		if attacker is player:
			if {gildie::%victim%::tag} is set:
				if {gildie::%attacker%::tag} is set:
					if {gildie::%victim%::tag} is {gildie::%attacker%::tag}:
						if {gildie::gildia::%{gildie::%attacker%::tag}%::pvp} is false:
							cancel event

# on join event #
on join:
	set {chat.%player%.cooldown} to 0
	if {gildie::%player%::status} is true:
		set {_opis} to "%{gildie::gildia::%{gildie::%player%::tag}%::opis}%"
		send "&7» &7Wiadomosc od gildii: &6%{_opis}%"
		loop {gildie::gildia::%{gildie::%player%::tag}%::czlonkowie::*}:
			send "&7» &7Gracz &6%player% &7z twojej gildii dolaczyl do gry!" to loop-value parsed as player

# on load event #
on load:
	set {_guild-items} to "{@guild-items}"
	replace all " and" with "," in {_guild-items}
	set {guild-items-text} to {_guild-items}
	loop {cuboids::*}:
		"%loop-value%".Region.selectLS{{cuboids::%loop-value%::location}, 50};

# on chat event #
on chat:
	cancel event
	set {_chat} to "{@chat}"
	replace all "{PLAYER}" with "%player%" in {_chat}
	replace all "{MESSAGE}" with "%message%" in {_chat}
	replace all "{GUILD}" with "%{gildie::%player%::tag}%" in {_chat}
	replace all "{RANK}" with "%colored player's prefix%" in {_chat}
	replace all "<none>" with "" in {_chat}
	if {chat.%player%.cooldown} is 0:
		broadcast "%{_chat}%"
		set {chat.%player%.cooldown} to 4
	else:
		send "&7Nastepna wiadomosc mozesz napisac za &2%{chat.%player%.cooldown}% &7sekund."

every 1 second:
	loop all players:
		if {chat.%loop-player%.cooldown} is not 0:
			remove 1 from {chat.%loop-player%.cooldown}