#AxCooldown - Skrypt na proste zarządzanie cooldownem
#$ Wersja 2.2.7 $#

on load:
    set {AxUpdate::AxCooldown::link} to "https://code.skript.pl/gJxAL9cd/raw"
    set {AxUpdate::AxCooldown::status} to true
    set {AxUpdate::AxCooldown::name} to "AxCooldown"
    set {AxUpdate::AxCooldown} to script
    
function createCooldown(name: text, time: timespan=1 minute, bypass: boolean=false):
    set {Cooldown::%{_name}%} to {_time}
    set {Cooldown::%{_name}%::bypass} to {_bypass} 
function deleteCooldown(name: text):
    delete {Cooldown::%{_name}%} and {Cd::%{_name}%::*}
function setCooldown(p: player, name: text, stat: boolean=true):
    set {Cd::%{_name}%::%{_p}%} to now
    if {_stat} is false:
        remove {Cooldown::%{_name}%} from {Cd::%{_name}%::%{_p}%}
function getCooldown(p: player, name: text, setCooldown: boolean=false) :: boolean:
    if {Cooldown::%{_name}%::bypass} is true:
        if {_p} has permission "cooldown.%{_name}%" or "*":
            return true
    if {Cd::%{_name}%::%{_p}%} is set:
        if difference between {Cd::%{_name}%::%{_p}%} and now >= {Cooldown::%{_name}%}:
            setCooldown({_p}, {_name}) if {_setCooldown} is true
            return true
        return false
    return true
function getCooldownBoolean(p: player, name: text) :: boolean:
    return getCooldown({_p}, {_name})
function getCooldownTime(p: player, name: text) :: timespan:
    set {_time} to {Cooldown::%{_name}%}
    remove (difference between {Cd::%{_name}%::%{_p}%} and now) from {_time}
    return {_time}
function getCooldownDate(p: player, name: text) :: date:
    set {_t} to now
    add getCooldownTime({_p}, {_name}) to {_t}
    return {_t}
function getCooldownText(p: player, name: text, format: texts=("l" and "l", "msc", "msc", "d", "d", "h", "h", "m", "m", "s", "s", ",")) :: text:
    set {_return} to "%getCooldownTime({_p}, {_name})%"
    loop ({_return} split at " "):
        if (loop-value parsed as number) is set:
            replace all loop-value with "%rounded (loop-value parsed as number)%" in {_return}
    set {_ang::*} to (" years" and " year", " months", " month", " days", " day", " hours" , " hour", " minutes", " minute", " seconds", " second", " and")
    loop {_ang::*}:
        replace all loop-value with ({_format::%loop-index%} ? {_ang::%loop-index%}) in {_return}
    return {_return}