Options:
    Prefix: &f[&aWm-login&f]
    # Kolory
    # 0 - czarny           3 - cyjanowy   6 - pomarańczowy   9 - lazurowy          c - jasno szerwony
    # 1 - granatowy        4 - czerwony   7 - jasno szary    a - limonkowy         d - magenta
    # 2 - ciemno zielony   5 - różowy     8 - ciemno szary   b - jasno niebieski   e - żółty
    Cooldown logowania: 60 # W sekundach
    Kolor błędu: c # Kolor, gdy jest błąd
    Kolor ok: a # Kolor, gdy jest powodzienie
    Kolor pomocy: e
    Maksymalna długość hasła: 16
    Minimalna długość hasła: 3
    Wiadomość o braku permisji do komendy admina: &cBrak permisji!
    SpawnCountdown: 5
    Info o graczu online: Ten gracz jest już online!

#  /$$   /$$  /$$$$$$  /$$$$$$$
# | $$  /$$/ /$$__  $$| $$__  $$
# | $$ /$$/ | $$  \ $$| $$  \ $$
# | $$$$$/  | $$  | $$| $$  | $$
# | $$  $$  | $$  | $$| $$  | $$
# | $$\  $$ | $$  | $$| $$  | $$
# | $$ \  $$|  $$$$$$/| $$$$$$$/
# |__/  \__/ \______/ |_______/
function tpspawn(player: player):
    teleport {_player} to {Wm-login::spawn-%{_player}'s world%}
    send action bar "&a&lSukces!" to {_player}
function countdown(player: player):
    set {_spawn_countdown} to {@SpawnCountdown}
    set {_spawn_countdown_location} to location of block at location of {_player}
    loop {_spawn_countdown} times:
        set {_spawn_countdown_location_check} to location of block at location of {_player}
        if {_spawn_countdown_location} = {_spawn_countdown_location_check}:
            send action bar "&a&lNie ruszaj się przez %{_spawn_countdown}% sekund!" to {_player}
        else:
            send action bar "&c&lTeleportacja anulowana, ruszyłeś/-aś się!" to {_player}
            stop
        subtract 1 from {_spawn_countdown}
        wait 1 second
    tpspawn({_player})

variables:
    {Wm-login::version} = "R3"
on skript load:
    send "[Wm-login] &aWersja: &6%{Wm-login::version}%"
    send "[Wm-login] &aPrzez: &6MiloNN"
    set {Wm-login::check-version} to text from "https://womimc.github.io/Wm-login-api/version.txt"
    if {Wm-login::check-version} = {Wm-login::version}:
        send "[Wm-login] &aUżywasz najnowszej wersji!"
    else:
        send "[Wm-login] &6Dostępna aktualizacja! Używana wersja: %{Wm-login::version}% | Najnowsza wersja: %{Wm-login::check-version}%"
on skript unload:
    send "[Wm-login] &cWyłączanie..."
on connect:
    if number of all players > 0:
        send "&a&l+ &cŁączenie gracza &6%player%!" to all operators
    set {Wm-login::players::*} to all players
    if "%{Wm-login::players::*}%" contains "%player%":
        kick player due to "{@Prefix}&{@Kolor błędu} {@Info o graczu online}"
on disconnect:
    if number of all players > 0:
        send "&4&l- &cRozłączono gracza &6%player%!" to all operators
on player move:
    if {Wm-login::log-%player's uuid%} is not set:
        cancel event
on drop:
    if {Wm-login::log-%player's uuid%} is not set:
        cancel event
on damage:
    if {Wm-login::log-%victim's uuid%} is not set:
        if victim is player:
            heal victim
on inventory open:
    if {Wm-login::log-%player's uuid%} is not set:
        cancel event
on teleport:
    if {Wm-login::log-%player's uuid%} is not set:
        cancel event
on player interact:
    if {Wm-login::log-%player's uuid%} is not set:
        cancel event
on command:
    if executor is not console:
        if {Wm-login::log-%player's uuid%} is not set:
            cancel event
            send "{@Prefix}&{@Kolor błędu} Podaj hasło na czacie!"
on join:
    clear player's inventory
    teleport player to {Wm-login::spawn}
    if {Wm-login::%player's uuid%-autolog} = player's ip:
        send "{@Prefix}&{@Kolor ok} Pomyślnie zalogowano!"
        set {Wm-login::log-%player's uuid%} to true
        send title "&{@Kolor ok}&lWeryfikacja!" with subtitle "&7Pomyślnie się zalogowano!" to the player for 2 second
        send "{@Prefix}&{@Kolor ok} Gracz %player% został zalogowany automatycznie!" to console
    else:
        delete {Wm-login::log-%player's uuid%}
    if {Wm-login::%player's uuid%::pass} is set:
        if {Wm-login::log-%player's uuid%} is not set:
            apply blindness potion of tier 255 to the player for 1 day
            send title "&{@Kolor ok}&lZaloguj się!" with subtitle "&7Wprowadź hasło na czacie!" to player for 1 day
    if {Wm-login::%player's uuid%::pass} is not set:
        apply blindness potion of tier 255 to the player for 1 day
        send title "&{@Kolor ok}&lZarejestruj się!" with subtitle "&7Wprowadź hasło na czacie!" to player for 1 day
    set {_cooldown} to {@Cooldown logowania}
    loop {_cooldown} times:
        if {Wm-login::log-%player's uuid%} is set:
            stop
        send action bar "&a&lMasz %{_cooldown}% sekund na zalogowanie się!"
        subtract 1 from {_cooldown}
        wait 1 second
    kick player due to "&cLogowanie trwało zbyt długo!"
on chat:
    if {Wm-login::%player's uuid%::pass} is set:
        if {Wm-login::log-%player's uuid%} is not set:
            cancel event
            if message hashed with SHA-256 is {Wm-login::%player's uuid%::pass}:
                send "{@Prefix}&{@Kolor ok} Pomyślnie zalogowano!"
                wait 1 tick
                set {Wm-login::log-%player's uuid%} to true
                remove blindness from player
                send title "&{@Kolor ok}&lWeryfikacja!" with subtitle "&7Pomyślnie się zalogowano!" for 2 second
                send "{@Prefix}&{@Kolor ok} Gracz %player% został pomyślnie zalogowany!" to console
            else:
                send "{@Prefix}&{@Kolor błędu} Błędne hasło!"
        else:
            stop
    if {Wm-login::%player's uuid%::pass} is not set:
        if {Wm-login::log-%player's uuid%} is not set:
            cancel event
            if length of message >= {@Minimalna długość hasła}:
                if length of message <= {@Maksymalna długość hasła}:
                    send "{@Prefix}&{@Kolor ok} Pomyślnie zarejestrowano!"
                    set {Wm-login::%player's uuid%::pass} to message hashed with SHA-256
                    wait 1 tick
                    set {Wm-login::log-%player's uuid%} to true
                    remove blindness from player
                    send title "&{@Kolor ok}&lWeryfikacja!" with subtitle "&7Pomyślnie zarejestrowano!" to player for 2 seconds
                    send "{@Prefix}&{@Kolor ok} Gracz %player% został pomyślnie zarejestrowany!" to console
                else:
                    send "{@Prefix}&{@Kolor błędu} Hasło jest za długie!"
                    send "{@Prefix}&{@Kolor ok} Hasło musi mieć od {@Minimalna długość hasła} do {@Maksymalna długość hasła}"
            else:
                send "{@Prefix}&{@Kolor błędu} Hasło jest za krótkie!"
                send "{@Prefix}&{@Kolor ok} Hasło musi mieć od {@Minimalna długość hasła} do {@Maksymalna długość hasła}"
        else:
            stop
    else:
        stop
command /unregister:
    executable by: players
    aliases: unreg, wyrejestruj, odrejestruj
    trigger:
        if {Wm-login::%player's uuid%::pass} is set:
            if {Wm-login::log-%player's uuid%} is true:
                delete {Wm-login::%player's uuid%::pass}
                delete {Wm-login::%player's uuid%-autolog}
                kick player due to "&{@Kolor ok} Pomyślnie wyrejestrowano!%nl%&{@Kolor ok} Proszę ponownie dołączyć na serwer!"
            else:
                send "{@Prefix}&{@Kolor błędu} Musisz być zalogowany/-a, aby tego użyć!"
        else:
            send "{@Prefix}&{@Kolor błędu} Nie jesteś jeszcze zarejestrowany!"
command /logout:
    executable by: players
    aliases: wyloguj, unlogin, unlog
    trigger:
        if {Wm-login::%player's uuid%::pass} is set:
            if {Wm-login::log-%player's uuid%} is true:
                kick player due to "&{@Kolor ok} Pomyślnie wylogowano!%nl%&{@Kolor ok} Proszę ponownie dołączyć na serwer!"
            else:
                send "{@Prefix}&{@Kolor błędu} Nie jesteś jeszcze zalogowany/-a!"
        else:
            send "{@Prefix}&{@Kolor błędu} Nie jesteś jeszcze zarejestrowany/-a!"
command /autologin:
    executable by: players
    aliases: autol, autolog, auto-l, auto-log, auto-login
    trigger:
        if {Wm-login::%player's uuid%::pass} is set:
            if {Wm-login::log-%player's uuid%} is true:
                if {Wm-login::%player's uuid%-autolog} is not set:
                    set {Wm-login::%player's uuid%-autolog} to player's ip
                    send "{@Prefix}&{@Kolor ok} Pomyślnie włączono auto-logowanie!"
                else if {Wm-login::%player's uuid%-autolog} is set:
                    delete {Wm-login::%player's uuid%-autolog}
                    send "{@Prefix}&{@Kolor ok} Pomyślnie wyłączono auto-logowanie!"
            else:
                send "{@Prefix}&{@Kolor błędu} Musisz być zalogowany/-a, aby tego użyć!"
        else:
            send "{@Prefix}&{@Kolor błędu} Musisz być zarejestrowany/-a, aby tego użyć!"
command /clearchat:
    aliases: cc, clearc, cchat, clear-chat, c-c, clear-c, c-chat
    permission: clearchat.use
    permission message: {@Prefix}&{@Kolor błędu} Nie masz uprawnień!
    trigger:
        loop 200 times:
            send " " to all players
        send "&8&l&m+-----------------------------------------------------------------------------+&r" to all players
        send "&aCzat został wyczyszczony przez administratora &6%player%&r" to all players
        send "&8&l&m+-----------------------------------------------------------------------------+&r" to all players
command /spawn [<text>]:
    aliases: spawn:spawn
    trigger:
        countdown(player)
command /lobby:
    trigger:
        if {Wm-login::lobby} is set:
            teleport player to {Wm-login::lobby}
        else:
            send "{@Prefix}&{@Kolor błędu} Lobby nie zostało ustawione!"
command /wm-admin [<text>]:
    executable by: players
    permission: wm-l.admin
    permission message: {@Wiadomość o braku permisji do komendy admina}
    trigger:
        if arg-1 is "setlobby":
            set {Wm-login::lobby} to player's location
            send "{@Prefix}&{@Kolor ok} Pomyślnie ustawiono lobby!"
        else if arg-1 is "dellobby":
            delete {Wm-login::lobby}
            send "{@Prefix}&{@Kolor ok} Pomyślnie usunięto lobby!"
        else if arg-1 is "setspawn":
            set {Wm-login::spawn-%player's world%} to player's position
            set {Wm-login::spawn-%player's world%-text} to "%{Wm-login::spawn-%player's world%}%"
            replace all "in" with "w" in {Wm-login::spawn-%player's world%-text}
            replace all "'" with "" in {Wm-login::spawn-%player's world%-text}
            send "{@Prefix}&{@Kolor ok} Ustawiono spawn na &6%{Wm-login::spawn-%player's world%-text}%"
        else if arg-1 is "delspawn":
            delete {Wm-login::spawn-%player's world%}
            send "{@Prefix}&{@Kolor ok} Usunięto spawn!"
        else if arg-1 is "help" or "pomoc":
            send "{@Prefix}&{@Kolor pomocy} Lista komend:"
            send "{@Prefix}&{@Kolor pomocy} /wm-admin help/pomoc &{@Kolor ok}- pokazuje tę listę."
            send "{@Prefix}&{@Kolor pomocy} /wm-admin setlobby &{@Kolor ok}- ustawia lobby."
            send "{@Prefix}&{@Kolor pomocy} /wm-admin dellobby &{@Kolor ok}- usuwa lobby."
            send "{@Prefix}&{@Kolor pomocy} /wm-admin setspawn &{@Kolor ok}- ustawia spawn."
            send "{@Prefix}&{@Kolor pomocy} /wm-admin delspawn &{@Kolor ok}- usuwa spawn."
            send "{@Prefix}&{@Kolor pomocy} /spawn &{@Kolor ok}- teleportuje na spawn."
        else:
            send "{@Prefix}&{@Kolor pomocy} Lista komend:"
            send "{@Prefix}&{@Kolor pomocy} /wm-admin help/pomoc &{@Kolor ok}- pokazuje tę listę."
            send "{@Prefix}&{@Kolor pomocy} /wm-admin setlobby &{@Kolor ok}- ustawia lobby."
            send "{@Prefix}&{@Kolor pomocy} /wm-admin dellobby &{@Kolor ok}- usuwa lobby."
            send "{@Prefix}&{@Kolor pomocy} /wm-admin setspawn &{@Kolor ok}- ustawia spawn."
            send "{@Prefix}&{@Kolor pomocy} /wm-admin delspawn &{@Kolor ok}- usuwa spawn."
            send "{@Prefix}&{@Kolor pomocy} /spawn &{@Kolor ok}- teleportuje na spawn."
            
command /wm-l-admin [<text>] [<player>] [<text>] [<text>] [<text>]:
    executable by: console
    trigger:
        if arg-1 is not set:
            execute console command "wm-l-admin help"
        else if arg-1 is "help" or "pomoc":
            send "{@Prefix}&{@Kolor pomocy} Lista komend:"
            send "{@Prefix}&{@Kolor pomocy} /wm-l-admin help/pomoc &{@Kolor ok}- pokazuje tę listę."
            send "{@Prefix}&{@Kolor pomocy} /wm-l-admin changepass <gracz> <hasło> <potwierdź hasło> &{@Kolor ok}- zmienia hasło podanego gracza."
            send "{@Prefix}&{@Kolor pomocy} /wm-l-admin forcelog <gracz> &{@Kolor ok}- wymusza zalogowanie podanego gracza."
            send "{@Prefix}&{@Kolor pomocy} /wm-l-admin forcereg <gracz> <hasło> <potwierdź hasło> &{@Kolor ok}- wymusza zarejestrowanie podanego gracza."
        else if arg-1 is "unregister":
            if arg-2 is set:
                delete {Wm-login::%arg-2's uuid%::pass}
                delete {Wm-login::%arg-2's uuid%-autolog}
                kick arg-2 due to "&{@Kolor ok} Pomyślnie wyrejestrowano przez administratora!%nl%&{@Kolor ok} Proszę ponownie dołączyć na serwer!"
                delete {Wm-login::unregister-confirm}
            else:
                send "{@Prefix}&{@Kolor błędu} Podaj nick gracza!"
        else if arg-1 is "forcelog":
            if arg-2 is set:
                if arg-3 is not set:
                    send "{@Prefix}&{@Kolor ok} Pomyślnie zalogowano!" to the arg-2
                    send "{@Prefix}&{@Kolor ok} Zalogowano przez administratora!" to the arg-2
                    set {Wm-login::log-%arg-2's uuid%} to true
                    remove blindness from arg-2
                    send title "&{@Kolor ok}&lWeryfikacja!" with subtitle "&7Pomyślnie się zalogowano!" to arg-2 for 2 second
                else:
                    send "{@Prefix}&{@Kolor błędu} Za dużo argumentów!"
            else:
                send "{@Prefix}&{@Kolor błędu} Podaj gracza!"
        else if arg-1 is "forcereg":
            if arg-2 is set:
                if arg-3 is set:
                    if arg-4 is set:
                        if arg-3 = arg-4:
                            if arg-5 is not set:
                                send "{@Prefix}&{@Kolor ok} Pomyślnie zarejestrowano!" to the arg-2
                                send "{@Prefix}&{@Kolor ok} Zarejestrowano przez administratora!" to the arg-2
                                send "{@Prefix}&{@Kolor ok} Twoje hasło to: %arg-3%!" to the arg-2
                                set {Wm-login::%arg-2's uuid%::pass} to arg-3 hashed with SHA-256
                                set {Wm-login::log-%arg-2's uuid%} to true
                                remove blindness from arg-2
                                send title "&{@Kolor ok}&lWeryfikacja!" with subtitle "&7Pomyślnie się zarejestrowano!" to arg-2 for 2 second
                            else:
                                send "{@Prefix}&{@Kolor błędu} Za dużo argumentów!"
                        else:
                            send "{@Prefix}&{@Kolor błędu} Hasła nie są takie same!"
                    else:
                        send "{@Prefix}&{@Kolor błędu} Podtwierdź hasło!"
                else:
                    send "{@Prefix}&{@Kolor błędu} Podaj hasło!"
            else:
                send "{@Prefix}&{@Kolor błędu} Podaj gracza!"
        else:
            send "{@Prefix}&{@Kolor błędu} Błędny agrument!"
            execute console command "wm-l-admin help"
command /adminchat [<text>]:
    permission: wm-login.adminchat.use
    permission message: {@Prefix}&{@Kolor błędu} Nie masz uprawnień, aby użyć tej komendy!
    trigger:
        if arg-1 is not set:
            send "{@Prefix}&{@Kolor błędu} Podaj wiadomość!"
        else:
            loop all players:
                if loop-player has permission "wm-adminchat.use":
                    send "{@Prefix} &f[&aAdminChat&f] &4%player%&f: %arg-1%" to loop-player