# jChat - skrypt do obsługi czatu
# Autor: Jqmey
# Wersja: v0.1.4 beta

variables:
	{jChat.czat} = true
	{jChat.cl-dystans} = 100
	{jChat.wppl} = false
	{jChat.wppl-dlugosc} = 0
	{jChat.%player%.wyciszenie} = false
	{jChat.%player%.wyciszenie-czas} = 0
	{jChat.%player%.wyciszenie-dozywotnie} = false
	{jChat.%player%.czat-pogrubienie} = false
	{jChat.%player%.czat-kolor} = "&2"
	{jChat.%player%.trybczatuadministracyjnego} = false
	{jChat.%player%.trybczatulokalnego} = false

every 60 seconds:
	loop all players:
		if {jChat.%loop-player%.wyciszenie} is true:
			if {jChat.%loop-player%.wyciszenie-dozywotnie} is false:
				remove 1 from {jChat.%loop-player%.wyciszenie-czas}
				if {jChat.%loop-player%.wyciszenie-czas} is less or equal to 0:
					set {jChat.%loop-player%.wyciszenie} to false
					set {jChat.%loop-player%.wyciszenie-czas} to 0

command /jchat informacje:
	description: Pomoc skryptu jChat.
	usage: /jchat informacje
	executable by: players and console
	trigger:
		send "jChat - skrypt do zarządzania czatem"
		send "Autor: Jqmey"
		send "Wersja: 0.1.4 beta"

command /użytkownicy [<text>] [<text>] [<text>]:
	description: Zarządza wyglądem nazw użytkowników.
	usage: /użytkownicy [użytkownik] [opcja] [wartość]
	permission: jchat.uzytkownicy
	permission message: &4Nie masz wystarczających uprawnień, aby zarządzać użytkownikami!
	executable by: players and console
	aliases: uzytkownicy
	trigger:
		if argument 1 is not set:
			send "&6Dostępne opcje:"
			send "&5/użytkownicy <użytkownik>&6 - wyświetlenie informacji o aktualnym formatowaniu użytkownika"
			send "&5/użytkownicy <użytkownik> pogrubienie tak/nie&6 - włączanie i wyłączanie pogrubienia nazwy użytkownika"
			send "&5/użytkownicy <użytkownik> kolor <kod koloru np. 1, f itd.>&6 - zmiana kolory nazwy użytkownika"
		else:
			if argument 2 is not set:
				if {jChat.%argument 1%.czat-pogrubienie} is true:
					send "&6Aktualne formatowanie użytkownika: %colored {jChat.%argument 1%.czat-kolor}%&l%player%"
				else:
					send "&6Aktualne formatowanie użytkownika: %colored {jChat.%argument 1%.czat-kolor}%%player%"
			else:
				if argument 2 is "pogrubienie" or "kolor":
					if argument 2 is "pogrubienie":
						if argument 3 is "tak":
							set {jChat.%argument 1%.czat-pogrubienie} to true
							send "&6Włączono pogrubienie nazwy użytkownika %argument 1%."
						else if argument 3 is "nie":
							set {jChat.%argument 1%.czat-pogrubienie} to false
							send "&6Wyłączono pogrubienie nazwy użytkownika %argument 1%."
						else:
							send "&4Nieprawidłowy argument!"
					else:
						set {jChat.%argument 1%.czat-kolor} to "&%argument 3%"
						send "&6Ustawiono kolor &6dla użytkownika %argument 1%."
				else:
					send "&4Nieprawidłowy argument!"

command /opcje [<text>] [<text>]:
	description: Zmienia opcje skryptu.
	usage: /opcje [opcja] [wartość]
	permission: jchat.opcje
	permission message: &4Nie masz wystarczających uprawnień, aby zarządzać opcjami!
	executable by: players and console
	trigger:
		if argument 1 is not set:
			send "&6Dostępne opcje:"
			send "&5/opcje dcl <dystans>&6 - ustawia dystans czatu lokalnego"
			send "&5/opcje wppl <czas>/nie&6 - ustawia wyciszenie przy pierwszym logowaniu"
		else:
			if argument 1 is "dcl" or "wppl":
				if argument 1 is "dcl":
					if argument 2 is number:
						set {jChat.cl-dystans} to argument 2
						send "&6Zmieniono dystans czatu lokalnego na %argument 2%."
					else:
						send "&4Nieprawidłowy argument!"
				else:
					if argument 2 is number:
						set {jChat.wppl} to true
						set {jChat.wppl-dlugosc} to argument 2
						send "&6Zmieniono długość wyciszenia przy pierwszym logowaniu na %argument 2%."
					else:
						set {jChat.wppl} to false
						set {jChat.wppl-dlugosc} to 0
						send "&6Wyłączono wyciszenie przy pierwszym logowaniu."
			else:
				send "&4Nieprawidłowy argument!"

on chat:
	cancel event
	if {jChat.%player%.wyciszenie} is true:
		if {jChat.%player%.wyciszenie-dozywotnie} is true:
			send "&4Jesteś wyciszony dożywotnie!"
		else:
			send "&4Jesteś wyciszony! Pozostało %{jChat.%player%.wyciszenie-czas}% minut do końca."
	else:
		if {jChat.%player%.trybczatuadministracyjnego} is false:
			if {jChat.czat} is true:
				if {jChat.%player%.trybczatulokalnego} is true:
					loop all players:
						if distance between player and loop-player is less than {jChat.cl-dystans}:
							if {jChat.%player%.czat-pogrubienie} is true:
								send "&7[Czat lokalny] %colored {jChat.%player%.czat-kolor}%&l%player%:&r %message%" to loop-player
							else:
								send "&7[Czat lokalny] %colored {jChat.%player%.czat-kolor}%%player%:&r %message%" to loop-player
				else:
					if {jChat.%player%.czat-pogrubienie} is true:
						broadcast "%colored {jChat.%player%.czat-kolor}%&l%player%:&r %message%"
					else:
						broadcast "%colored {jChat.%player%.czat-kolor}%%player%:&r %message%"
			else:
				player has permission "jchat.ominieciewylaczenia":
					if {jChat.%player%.trybczatulokalnego} is true:
						loop all players:
							if distance between player and loop-player is less than {jChat.cl-dystans}:
								if {jChat.%player%.czat-pogrubienie} is true:
									send "&7[Czat lokalny] %colored {jChat.%player%.czat-kolor}%&l%player%:&r %message%" to loop-player
								else:
									send "&7[Czat lokalny] %colored {jChat.%player%.czat-kolor}%%player%:&r %message%" to loop-player
					else:
						if {jChat.%player%.czat-pogrubienie} is true:
							broadcast "%colored {jChat.%player%.czat-kolor}%&l%player%:&r %message%"
						else:
							broadcast "%colored {jChat.%player%.czat-kolor}%%player%:&r %message%"
				else:
					send "&4Czat jest aktualnie wyłączony!"
		else:
			loop all players:
				loop-player has permission "jchat.czatadministracyjny":
					if {jChat.%player%.czat-pogrubienie} is true:
						send "&8[Czat administracyjny] %colored {jChat.%player%.czat-kolor}%&l%player%:&r %message%" to loop-player
					else:
						send "&8[Czat administracyjny] %colored {jChat.%player%.czat-kolor}%%player%:&r %message%" to loop-player

on first join:
	if {jChat.wppl} is true:
		execute console command "/wycisz %player% %{jChat.wppl-dlugosc}%"
		send "&4Ze względu na zabezpieczenia serwera pisanie na czacie jest możliwe po %{jChat.wppl-dlugosc}% minutach."
	broadcast "&9&l[Ogłoszenie]&r Witamy nowego gracza na serwerze: %player%!"

on join:
	if {jChat.%player%.czat-pogrubienie} is true:
		set join message to "%colored {jChat.%player%.czat-kolor}%&l%player%&r wszedł na serwer!"
	else:
		set join message to "%colored {jChat.%player%.czat-kolor}%%player%&f wszedł na serwer!"

on quit:
	if {jChat.%player%.czat-pogrubienie} is true:
		set leave message to "%colored {jChat.%player%.czat-kolor}%&l%player%&r opuścił serwer!"
	else:
		set leave message to "%colored {jChat.%player%.czat-kolor}%%player%&f opuścił serwer!"

on death:
	if {jChat.%player%.czat-pogrubienie} is true:
		set death message to "%colored {jChat.%player%.czat-kolor}%&l%player%&r zginął!"
	else:
		set death message to "%colored {jChat.%player%.czat-kolor}%%player%&f zginął!"

command /wycisz <player> [<number>]:
	description: Wycisza gracza.
	usage: /wycisz <gracz> [czas w minutach]
	permission: jchat.wyciszanie
	permission message: &4Nie masz wystarczających uprawnień, aby wyciszać graczy!
	executable by: players and console
	aliases: mute
	trigger:
		if argument 2 is not set:
			set {jChat.%argument 1%.wyciszenie} to true
			set {jChat.%argument 1%.wyciszenie-dozywotnie} to true
			log "Moderator %player% wyciszył dożywotnio użytkownika %argument 1%." to "jChat.log"
			send "&3Wyciszono dożywotnio użytkownika %argument 1%."
			loop all players:
				loop-player has permission "jchat.widzenie":
					if loop-player is not player:
						send "&3Moderator %player% wyciszył dożywotnio użytkownika %argument 1%." to loop-player
		else:
			if argument 2 is number:
				set {jChat.%argument 1%.wyciszenie-dozywotnie} to false
				set {jChat.%argument 1%.wyciszenie} to true
				set {jChat.%argument 1%.wyciszenie-czas} to argument 2
				log "Moderator %player% wyciszył na %argument 2% minut użytkownika %argument 1%." to "jChat.log"
				send "&3Wyciszono na %argument 2% minut użytkownika %argument 1%."
				loop all players:
					loop-player has permission "jchat.widzenie":
						if loop-player is not player:
							send "&3Moderator %player% wyciszył na %argument 2% minut użytkownika %argument 1%." to loop-player
			else:
				send "&4Nieprawidłowy argument!"

command /przedłuż <player> <number>:
	description: Przedłuża wyciszenie gracza.
	usage: /przedłuż <gracz> <czas w minutach>
	permission: jchat.wyciszanie
	permission message: &4Nie masz wystarczających uprawnień, aby przedłużać wyciszenie graczy!
	executable by: players and console
	aliases: przedluz
	trigger:
		if argument 2 is number:
			set {jChat.%argument 1%.wyciszenie-dozywotnie} to false
			set {jChat.%argument 1%.wyciszenie} to true
			add argument 2 to {jChat.%argument 1%.wyciszenie-czas}
			log "Moderator %player% przedłużył o %argument 2% minut wyciszenie użytkownika %argument 1%." to "jChat.log"
			send "&3Przedłużono o %argument 2% minut wyciszenie użytkownika %argument 1%."
			loop all players:
				loop-player has permission "jchat.widzenie":
					if loop-player is not player:
						send "&3Moderator %player% przedłużył o %argument 2% minut wyciszenie użytkownika %argument 1%." to loop-player
		else:
			send "&4Nieprawidłowy argument!"

command /odwycisz <player>:
	description: Odwycisza gracza.
	usage: /odwycisz <gracz>
	permission: jchat.wyciszanie
	permission message: &4Nie masz wystarczających uprawnień, aby odwyciszać graczy!
	executable by: players and console
	aliases: unmute
	trigger:
		set {jChat.%argument 1%.wyciszenie-dozywotnie} to false
		set {jChat.%argument 1%.wyciszenie} to false
		set {jChat.%argument 1%.wyciszenie-czas} to 0
		log "Moderator %player% odwyciszył użytkownika %argument 1%." to "jChat.log"
		send "&3Odwyciszono użytkownika %argument 1%."
		loop all players:
			loop-player has permission "jchat.widzenie":
				if loop-player is not player:
					send "&3Moderator %player% odwyciszył użytkownika %argument 1%." to loop-player

command /sprawdź <player>:
	description: Sprawdza, czy gracz jest wyciszony.
	usage: /sprawdź <gracz>
	permission: jchat.sprawdzanie
	permission message: &4Nie masz wystarczających uprawnień, aby sprawdzać graczy!
	executable by: players and console
	aliases: sprawdz
	trigger:
		if {jChat.%argument 1%.wyciszenie} is false:
			send "&3Gracz %argument 1% nie jest wyciszony."
		else:
			if {jChat.%argument 1%.wyciszenie-dozywotnie} is true:
				send "&3Gracz %argument 1% jest wyciszony dożywotnio."
			else:
				send "&3Gracz %argument 1% jest wyciszony. Pozostało %{jChat.%argument 1%.wyciszenie-czas}% minut do końca."

command /listawyciszonych:
	description: Lista aktualnie wyciszonych graczy.
	usage: /listawyciszonych
	permission: jchat.sprawdzanie
	permission message: &4Nie masz wystarczających uprawnień, aby sprawdzać graczy!
	executable by: players and console
	trigger:
		loop all players:
			if {jChat.%loop-player%.wyciszenie} is true:
				if {jChat.%loop-player%.wyciszenie-dozywotnie} is true:
					send "&3%loop-player%"
				else:
					send "&3%loop-player% - pozostało %{jChat.%loop-player%.wyciszenie-czas}% minut"

command /ogłoszenie <text>:
	description: Publikuje ogłoszenie
	usage: /ogłoszenie <treść>
	permission: jchat.publikowanieogloszen
	permission message: &4Nie masz wystarczających uprawnień, aby publikować ogłoszenia!
	executable by: players and console
	aliases: ogloszenie, broadcast
	trigger:
		broadcast "&9&l[Ogłoszenie]&r %argument 1%"

command /czat:
	description: Przełącza czat.
	permission: jchat.przelaczanie
	permission message: &4Nie masz wystarczających uprawnień, aby przełączać czat!
	executable by: players and console
	aliases: chat
	trigger:
		if {jChat.czat} is true:
			set {jChat.czat} to false
			send "&6Wyłączono czat!"
		else:
			set {jChat.czat} to true
			send "&6Włączono czat!"

command /wyczyść:
	description: Czyści czat.
	permission: jchat.sprzatacz
	permission message: &4Nie masz wystarczających uprawnień, aby wyczyścić czat!
	executable by: players and console
	aliases: clear, cc
	trigger:
		loop 150 times:
			send "" to all players
		send "&6Wyczyszczono czat!"

command /czatadministracji <text>:
	description: Publikuje wiadomość na czacie administracji.
	permission: jchat.czatadministracji
	permission message: &4Nie masz wystarczających uprawnień, aby korzystać z czatu administracji!
	executable by: players and console
	aliases: ca, adminchat, ac
	trigger:
		loop all players:
			loop-player has permission "jchat.czatadministracji":
				if {jChat.%player%.czat-pogrubienie} is true:
					send "&8[Czat administracyjny] %colored {jChat.%player%.czat-kolor}%&l%player%:&r %argument 1%" to loop-player
				else:
					send "&8[Czat administracyjny] %colored {jChat.%player%.czat-kolor}%%player%:&r %argument 1%" to loop-player

command /czatlokalny <text>:
	description: Publikuje wiadomość na czacie lokalnym.
	permission: jchat.czatlokalny
	permission message: &4Nie masz wystarczających uprawnień, aby korzystać z czatu lokalnego!
	executable by: players and console
	aliases: cl, localchat, lc
	trigger:
		if {jChat.czat} is true:
			loop all players:
				if distance between player and loop-player is less than {jChat.cl-dystans}:
					if {jChat.%player%.czat-pogrubienie} is true:
						send "&7[Czat lokalny] %colored {jChat.%player%.czat-kolor}%&l%player%:&r %argument 1%" to loop-player
					else:
						send "&7[Czat lokalny] %colored {jChat.%player%.czat-kolor}%%player%:&r %argument 1%" to loop-player
		else:
			player has permission "jchat.ominieciewylaczenia":
				loop all players:
					if distance between player and loop-player is less than {jChat.cl-dystans}:
						if {jChat.%player%.czat-pogrubienie} is true:
							send "&7[Czat lokalny] %colored {jChat.%player%.czat-kolor}%&l%player%:&r %argument 1%" to loop-player
						else:
							send "&7[Czat lokalny] %colored {jChat.%player%.czat-kolor}%%player%:&r %argument 1%" to loop-player
			else:
				send "&4Czat jest aktualnie wyłączony!"

command /trybstały [<text>]:
	description: Przełącza tryb stały czatu administracji albo lokalnego.
	permission: jchat.trybstaly
	permission message: &4Nie masz wystarczających uprawnień, aby korzystać z trybu stałego!
	executable by: players and console
	aliases: trybstaly
	trigger:
		send "&6Dostępne opcje:"
		if argument 1 is not set:
			player has permission "jchat.czatadministracji":
				send "&5/trybstały ca&6 - uruchomienie tryby stałego czatu administracji"
			player has permission "jchat.czatlokalny":
				send "&5/trybstały cl&6 - uruchomienie tryby stałego czatu lokalnego"
		else:
			if argument 1 is "ca" or "cl":
				if argument 1 is "ca":
					player has permission "jchat.czatadministracji":
						if {jChat.%player%.trybczatuadministracyjnego} is true:
							set {jChat.%player%.trybczatuadministracyjnego} to false
							send "&6Wyłączono tryb stały czatu administracji."
						else:
							set {jChat.%player%.trybczatuadministracyjnego} to true
							send "&6Włączono tryb stały czatu administracji."
					else:
						send "&4Nie masz wystarczających uprawnień, aby przełączyć tryb stały czatu administracji!"
				else:
					player has permission "jchat.czatlokalny":
						if {jChat.%player%.trybczatulokalnego} is true:
							set {jChat.%player%.trybczatulokalnego} to false
							send "&6Wyłączono tryb stały czatu lokalnego."
						else:
							set {jChat.%player%.trybczatulokalnego} to true
							send "&6Włączono tryb stały czatu lokalnego."
					else:
						send "&4Nie masz wystarczających uprawnień, aby przełączyć tryb stały czatu lokalnego!"
			else:
				send "&4Taki czat nie istnieje!"