code.skript.pl - kod iwokcCR0

#
#  ░██╗░░██╗██╗░░░██╗██████╗░██╗██╗░░██╗███████╗██╗░░░░░░
#  ░██║░░██║╚██╗░██╔╝██╔══██╗██║╚██╗██╔╝██╔════╝██║░░░░░░
#  ░███████║░╚████╔╝░██████╔╝██║░╚███╔╝░█████╗░░██║░░░░░░
#  ░██╔══██║░░╚██╔╝░░██╔═══╝░██║░██╔██╗░██╔══╝░░██║░░░░░░
#  ░██║░░██║░░░██║░░░██║░░░░░██║██╔╝╚██╗███████╗███████╗░
#  ░╚═╝░░╚═╝░░░╚═╝░░░╚═╝░░░░░╚═╝╚═╝░░╚═╝╚══════╝╚══════╝░
#
#        ░░██████╗██╗░░██╗░█████╗░██████╗░░██████╗░
#        ░██╔════╝██║░░██║██╔══██╗██╔══██╗██╔════╝░
#        ░╚█████╗░███████║██║░░██║██████╔╝╚█████╗░░
#        ░░╚═══██╗██╔══██║██║░░██║██╔═══╝░░╚═══██╗░
#        ░██████╔╝██║░░██║╚█████╔╝██║░░░░░██████╔╝░
#        ░╚═════╝░╚═╝░░╚═╝░╚════╝░╚═╝░░░░░╚═════╝░░
#
# Wymagania:
#  ● Skript 2.6
#  ● Skacket
#  ● SkQuery
#  ● SkBee
#  ● Vault
#  ● Protocollib
#
options:
    version: 1.0.1
    author: PolsatGraniePL
#========================================================
#                        CONFIG
#========================================================
#
# Typ itemu jako tło sklepu:
    background-glass: light gray stained glass pane
    border-glass: black stained glass pane
#
#
# DOSTĘPNE PLACEHOLDERY:
#   ● {_item} - zwraca aktualnie kupiony/sprzedawany item w formacie "<ILOŚĆ> <ITEM>"
#   ● {_price} - zwraca cenę za kupiony/sprzedany item w formacie "<LICZBA>"
#   ● {_type} - zwraca typ aktualnie kuponego/sprzedawanego itemu w formacie "<TYP-ITEMU>"
#   ● {_amount} - zwraca ilość kupionych/sprzedanych itemów w formacie "<LICZBA>"
#    
    buyback-succes-message: " &8● &7Odkupiłeś &a%{_item}%&7 za &a$%{_price}%&7."
    buyback-failed-NoMoney: " &8● &cNie stać cię na to!"
    buyback-failed-NoSpace: " &8● &cNie masz miejsca w swoim inventory aby to odkupić!"
    buyback-failed-NoItem: " &8● &cNie masz już nic do odkupienia!"
    
    buy-succes-message: " &8● &7Kupiłeś &a%{_item}%&7 za &a$%{_price}%&7."
    buy-failed-NoMoney: " &8● &cNie stać cię na to!"
    buy-failed-NoSpace: " &8● &cNie zmieścisz tego do swojego inventory!"
    
    sell-succes-message: " &8● &7Sprzedałeś &a%{_item}%&7 za &a$%{_price}%&7."
    sell-failed-NoToSell: " &8● &cTen item nie jest na sprzedaż!"
    sell-failed-ItemHasName: " &8● &cNie możesz sprzedawać nazwanych itemów!"
#    
# KOMENDY:
#   
#  ● Główna komenda:
    shop-command: Sklep
    shop-command-permission: Hshop.shop.open
    shop-command-noperm-msg: &cNie masz permisji aby użyć tej komendy!
    shop-command-aliases: Shop, Shops
#   
#  ● Komnda edytora:
    editor-command: HypixelShops
    editor-command-permission: Hshop.editor
    editor-command-noperm-msg: &cNie masz permisji aby użyć tej komendy!
    editor-command-aliases: Hshop, HshopEditor
#
# Argumenty edytora:
    editor-arg-create: create
    editor-arg-edit: edit
    editor-arg-edit-items: items
    editor-arg-edit-price: price
    editor-arg-remove: remove
    editor-arg-list: list
#
# DŹWIĘKI:
    sound-enabled: true

sound-shop-open: entity.villager.celebrate
    sound-shop-close: entity.villager.ambient
    sound-shop-next: entity.villager.ambient
    sound-shop-sell-succes: entity.villager.yes
    sound-shop-buy-succes: entity.villager.trade
    sound-shop-failed: entity.villager.no

#========================================================

command /HshopReset:
    permission: *
    permission message: {@editor-command-noperm-msg}
    trigger:
        {Hshop::disabled} is not set
        delete {Hshop::*}
        send "&7Zresetowano skrypt %script%.sk!"

command /{@shop-command} [<text>]:
    permission: {@shop-command-permission}
    permission message: {@shop-command-noperm-msg}
    aliases: {@shop-command-aliases}
    trigger:
        {Hshop::disabled} is not set
        if {Hshop::shops::*} contains arg-1:
            open chest with 6 rows named "&8%arg-1%" to player
            set slot (integers between 0 and 45) of player's current inventory to {@background-glass} named "&7"
            set slot (integers between 0 and 9) of player's current inventory to {@border-glass} named "&7"
            set slot (integers between 17 and 18) of player's current inventory to {@border-glass} named "&7"
            set slot (17, 18, 26, 27, 35, 36) of player's current inventory to {@border-glass} named "&7"
            set slot (integers between 44 and 53) of player's current inventory to {@border-glass} named "&7"
            #
            ReloadBuyBack(player)
            SaveItemLoadLore(player)
            LoadItems(player, arg-1)
            #
            if {@sound-enabled} is true:
                play sound "{@sound-shop-open}" with volume 1 at player
            
function ReloadBuyBack(p: player):
    if {Hshop::LastSellPLR::%{_p}%::*} is not set:
        set slot 49 of {_p}'s current inventory to hopper named "&aSprzedaj Item" with lore "&7Kliknij na item w swoim EQ aby%nl%&7sprzedać dany przedmiot!"
    else:
        set {_} to size of {Hshop::LastSellPLR::%{_p}%::*}
        set slot 49 of {_p}'s current inventory to {Hshop::LastSellPLR::%{_p}%::%{_}%} with lore "%nl%&7Koszt%nl%&6%{Hshop::items::%type of {Hshop::LastSellPLR::%{_p}%::%{_}%}%::buy} * item amount of {Hshop::LastSellPLR::%{_p}%::%{_}%}% Monet%nl%%nl%&eKliknij aby odkupić!"
            
function LoadItems(p: player, type: text):
    set {_z} to 10
    loop {Hshop::shops::%{_type}%::*}:
        if {Hshop::items::%loop-value%::buy} <= 0:
            exit 1 section
        else:
            if {_z} is 17:
                add 2 to {_z}
            if {_z} is 26:
                add 2 to {_z}
            if {_z} is 35:
                add 2 to {_z}
            if {_z} is 44:
                add 2 to {_z}
            set slot {_z} of {_p}'s current inventory to loop-value with lore "%nl%&7Koszt%nl%&6%{Hshop::items::%loop-value%::buy}% Monet%nl% %nl%&eKliknij, aby handlować!"
            add 1 to {_z}
            
function SaveItemLoadLore(p: player):
    loop 36 times:
        add slot loop-value - 1 of {_p}'s inventory to {Hshop::player::%{_p}%::*}
    loop all items in {_p}'s inventory:
        name of loop-item is not set
        if {Hshop::items::%type of loop-item%::sell} is set:
            {Hshop::items::%type of loop-item%::sell} is not 0
            add "&8(x%item amount of loop-item%)%nl%%nl%&7Cena sprzedaży%nl%&6%{Hshop::items::%type of loop-item%::sell} * item amount of loop-item% Monet%nl% %nl%&eKliknij aby sprzedać!" to lore of loop-item
        
on inventory close:
    if {Hshop::shops::*} contains uncolored name of event-inventory:
        loop {Hshop::player::%player%::*}:
            set slot loop-index parsed as integer - 1 of player's inventory to loop-value
        delete {Hshop::player::%player%::*}
        if {@sound-enabled} is true:
            play sound "{@sound-shop-close}" with volume 1 at player
    if uncolored name of event-inventory contain " | Sklep":
        if {@sound-enabled} is true:
            play sound "{@sound-shop-close}" with volume 1 at player
    
on inventory click:
    if {Hshop::shops::*} contains uncolored name of event-inventory:
        cancel event
        if "%clicked inventory%" contains "inventory of <none>":
            name of event-item is not "&7"
            if clicked slot is 49:
                if event-item is not hopper named "&aSprzedaj Item" with lore "&7Kliknij na item w swoim EQ aby%nl%&7sprzedać dany przedmiot!":
                    if player has enough space for event-item:
                        if player's balance >= {Hshop::items::%type of event-item%::buy} * item amount of event-item:
                            set {_item} to event-item
                            set {_price} to {Hshop::items::%type of {_item}%::sell} * item amount of {_item}
                            set {_type} to type of event-item
                            set {_amount} to item amount of event-item
                            send {@buyback-succes-message}
                            if {@sound-enabled} is true:
                                play sound "{@sound-shop-buy-succes}" with volume 1 at player
                            clear lore of {_item}
                            loop all items in player's inventory:
                                loop lore of loop-item:
                                    if loop-value-2 is "&0*":
                                        remove line (size of lore of loop-item) of lore of loop-item from lore of loop-item
                            add "&8(x%item amount of {_item}%)%nl%%nl%&7Cena sprzedaży%nl%&6%{Hshop::items::%type of {_item}%::sell} * item amount of {_item}% Monet%nl% %nl%&eKliknij aby sprzedać!%nl%&0*" to lore of {_item}
                            give {_item} to player
                            remove {Hshop::items::%type of event-item%::buy} * item amount of event-item from player's balance
                            delete {Hshop::LastSellPLR::%player%::%size of {Hshop::LastSellPLR::%player%::*}%}
                            ReloadBuyBack(player)
                            loop {Hshop::player::%player%::*}:
                                if loop-value is air:
                                    clear lore of {_item}
                                    set {Hshop::player::%player%::%loop-index parsed as integer%} to {_item}
                                    stop
                            stop
                        send {@buyback-failed-NoMoney}
                        if {@sound-enabled} is true:
                            play sound "{@sound-shop-failed}" with volume 1 at player
                        stop
                    send {@buyback-failed-NoSpace}
                    if {@sound-enabled} is true:
                        play sound "{@sound-shop-failed}" with volume 1 at player
                    stop
                send {@buyback-failed-NoItem}
                if {@sound-enabled} is true:
                    play sound "{@sound-shop-failed}" with volume 1 at player
                stop
            set {_nameINV} to uncolored name of event-inventory
            open chest with 6 rows named "&8%{_nameINV}% | Sklep" to player
            set slot (integers between 0 and 45) of player's current inventory to {@background-glass} named "&7"
            set slot (integers between 0 and 9) of player's current inventory to {@border-glass} named "&7"
            set slot (integers between 17 and 18) of player's current inventory to {@border-glass} named "&7"
            set slot (17, 18, 26, 27, 35, 36) of player's current inventory to {@border-glass} named "&7"
            set slot (integers between 44 and 53) of player's current inventory to {@border-glass} named "&7"
            
            set slot 53 of player's current inventory to barrier named "&cWyjdź"
            set slot 45 of player's current inventory to arrow named "&aWróć" with lore "&7Do %{_nameINV}%"
            
            set slot 20 of player's current inventory to 1 of event-item with lore "%nl%&7Koszt%nl%&6%{Hshop::items::%type of event-item%::buy}% Monet%nl%%nl%&eKliknij aby kupić!"
            set slot 21 of player's current inventory to 5 of event-item with lore "%nl%&7Koszt%nl%&6%{Hshop::items::%type of event-item%::buy} * 5% Monet%nl%%nl%&eKliknij aby kupić!"
            set slot 22 of player's current inventory to 10 of event-item with lore "%nl%&7Koszt%nl%&6%{Hshop::items::%type of event-item%::buy} * 10% Monet%nl%%nl%&eKliknij aby kupić!"
            set slot 23 of player's current inventory to 32 of event-item with lore "%nl%&7Koszt%nl%&6%{Hshop::items::%type of event-item%::buy} * 32% Monet%nl%%nl%&eKliknij aby kupić!"
            set slot 24 of player's current inventory to 64 of event-item with lore "%nl%&7Koszt%nl%&6%{Hshop::items::%type of event-item%::buy} * 64% Monet%nl%%nl%&eKliknij aby kupić!"
            if {@sound-enabled} is true:
                play sound "{@sound-shop-next}" with volume 1 at player
        else:
            event-item is not air
            event-item is set
            if name of event-item is not set:
                if {Hshop::items::%type of event-item%::sell} is set:
                    {Hshop::items::%type of event-item%::sell} is not 0
                    set {_item} to event-item
                    set {_price} to {Hshop::items::%type of event-item%::sell} * item amount of event-item
                    set {_type} to type of event-item
                    set {_amount} to item amount of event-item
                    send {@sell-succes-message}
                    if {@sound-enabled} is true:
                        play sound "{@sound-shop-sell-succes}" with volume 1 at player
                    add event-item to {Hshop::LastSellPLR::%player%::*}
                    add {Hshop::items::%type of event-item%::sell} * item amount of event-item to player's balance
                    set slot 49 of player's current inventory to slot index of clicked slot of player's inventory with lore "%nl%&7Koszt%nl%&6%{Hshop::items::%type of event-item%::buy} * item amount of event-item% Monet%nl%%nl%&eKliknij aby odkupić!"
                    set slot index of clicked slot of player's inventory to air
                    set {Hshop::player::%player%::%index of clicked slot + 1%} to air
                    stop
                send {@sell-failed-NoToSell}
                if {@sound-enabled} is true:
                    play sound "{@sound-shop-failed}" with volume 1 at player
                stop
            send {@sell-failed-ItemHasName}
            if {@sound-enabled} is true:
                play sound "{@sound-shop-failed}" with volume 1 at player
    
    if uncolored name of event-inventory contain " | Sklep":
        cancel event
        if clicked slot is 53:
            close player's inventory
        if clicked slot is 45:
            set {_} to "%uncolored lore of event-item%"
            execute player command "{@shop-command} %subtext of {_} from characters 4 to (length of {_})%"
        if clicked slot is 20 or 21 or 22 or 23 or 24:
            if player's balance >= {Hshop::items::%type of event-item%::buy} * item amount of event-item:
                set {_item} to event-item
                set {_price} to {Hshop::items::%type of event-item%::buy} * item amount of event-item
                set {_type} to type of event-item
                set {_amount} to item amount of event-item
                delete {_item}'s lore
                if player doesn't have enough space for {_item}:
                    send {@buy-failed-NoSpace}
                    if {@sound-enabled} is true:
                        play sound "{@sound-shop-failed}" with volume 1 at player
                    stop
                give {_item} to player
                remove {Hshop::items::%type of event-item%::buy} * item amount of event-item from player's balance
                send {@buy-succes-message}
                if {@sound-enabled} is true:
                    play sound "{@sound-shop-buy-succes}" with volume 1 at player
                stop
            send {@buy-failed-NoMoney}
            if {@sound-enabled} is true:
                play sound "{@sound-shop-failed}" with volume 1 at player
            
on pickup:
    {Hshop::shops::*} contains uncolored name of player's current inventory
    cancel event
on drop:
    {Hshop::shops::*} contains uncolored name of player's current inventory
    cancel event
on death of player:
    {Hshop::shops::*} contains uncolored name of player's current inventory
    cancel event
            
# -- Editor --

on inventory click:
    if uncolored name of event-inventory contains " - Items Edytor":
        cancel event
        set {_edytowany} to uncolored name of event-inventory
        replace all " - Items Edytor" with "" in {_edytowany}
        if "%clicked inventory%" contains "inventory of <none>":
            event-item is set
            if clicked slot is barrier named "&cBrak slotu!":
                stop
            if clicked slot is redstone block named "&aJak obsługiwać Edytor itemów?":
                stop
            if click action is middle mouse button:
                remove event-item from {Hshop::editor::shop::%{_edytowany}%::*}
                ReloadEditor(player, {_edytowany}, "Items")
                stop
        else:
            event-item is not air
            event-item is set
            set {_item} to type of event-item
            if {Hshop::editor::shop::%{_edytowany}%::*} contain {_item}:
                send "&cTen item już jest w tym sklepie!"
                stop
            if size of {Hshop::editor::shop::%{_edytowany}%::*} = 28:
                send "&cNie zmieścisz więcej rzeczy do sklepu!"
                stop
            add {_item} to {Hshop::editor::shop::%{_edytowany}%::*}
            ReloadEditor(player, {_edytowany}, "Items")
            open sign to player with lines "", "^^^^^^^^", "Wpisz cenę (Kup)", "np. 0.01, 20 itp.":
                if 1rd element out of lines parsed as number is set:
                    set {Hshop::items::%{_item}%::buy} to 1rd element out of lines parsed as number
                    send "&7Ustawiono cenę kupna &a%{_item}%&7 na &a$%1rd element out of lines parsed as number%&7."
                    open sign to player with lines "", "^^^^^^^^", "Wpisz cenę (Sprzedaż)", "np. 0.01, 20 itp.":
                        if 1rd element out of lines parsed as number is set:
                            set {Hshop::items::%{_item}%::sell} to 1rd element out of lines parsed as number
                            send "&7Ustawiono cenę sprzedaży &a%{_item}%&7 na &a$%1rd element out of lines parsed as number%&7."
                            OpenEdytorItemsZcen(player, {_edytowany})
                            stop
                        send "&c""%1rd element out of lines%""&7 jest niepoprawną liczbą, ustawiono na niesprzedawalny przedmiot!"
                        set {Hshop::items::%{_item}%::sell} to 0
                        OpenEdytorItemsZcen(player, {_edytowany})
                        stop
                    stop
                send "&c""%1rd element out of lines%""&7 jest niepoprawną liczbą, ustawiono na 0!"
                set {Hshop::items::%{_item}%::buy} to 0
                open sign to player with lines "", "^^^^^^^^", "Wpisz cenę (Sprzedaż)", "np. 0.01, 20 itp.":
                    if 1rd element out of lines parsed as number is set:
                        set {Hshop::items::%{_item}%::sell} to 1rd element out of lines parsed as number
                        send "&7Ustawiono cenę sprzedaży &a%{_item}%&7 na &a$%1rd element out of lines parsed as number%&7."
                        OpenEdytorItemsZcen(player, {_edytowany})
                        stop
                    send "&c""%1rd element out of lines%""&7 jest niepoprawną liczbą, ustawiono na niesprzedawalny przedmiot!"
                    set {Hshop::items::%{_item}%::sell} to 0
                    OpenEdytorItemsZcen(player, {_edytowany})
                    stop
                    
    if uncolored name of event-inventory contains " - Edytor Cen":
        set {_edytowany} to uncolored name of event-inventory
        replace all " - Edytor Cen" with "" in {_edytowany}
        if "%clicked inventory%" contains "inventory of <none>":
            cancel event
            event-item is set
            set {_item} to type of event-item
            if clicked slot is barrier named "&cBrak slotu!":
                stop
            if clicked slot is redstone block named "&aJak obsługiwać Edytor Cen?":
                stop
            if click action is left mouse button:
                open sign to player with lines "", "^^^^^^^^", "Wpisz cenę (Kup)", "np. 0.01, 20 itp.":
                    if 1rd element out of lines parsed as number is set:
                        set {Hshop::items::%{_item}%::buy} to 1rd element out of lines parsed as number
                        send "&7Ustawiono cenę kupna &a%{_item}%&7 na &a$%1rd element out of lines parsed as number%&7."
                        OpenEdytorCen(player, {_edytowany})
                        stop
                    send "&c""%1rd element out of lines%""&7 jest niepoprawną liczbą!"
                    OpenEdytorCen(player, {_edytowany})
                    stop
            if click action is right mouse button:
                open sign to player with lines "", "^^^^^^^^", "Wpisz cenę (Sprzedaż)", "np. 0.01, 20 itp.":
                    if 1rd element out of lines parsed as number is set:
                        set {Hshop::items::%{_item}%::sell} to 1rd element out of lines parsed as number
                        send "&7Ustawiono cenę sprzedaży &a%{_item}%&7 na &a$%1rd element out of lines parsed as number%&7."
                        OpenEdytorCen(player, {_edytowany})
                        stop
                    send "&c""%1rd element out of lines%""&7 jest niepoprawną liczbą!"
                    OpenEdytorCen(player, {_edytowany})
                    stop
            if click action is left mouse button with shift:
                set {Hshop::items::%{_item}%::buy} to 0
                send "&7Zresetowałeś cenę kupna dla&8: &a%{_item}%"
                OpenEdytorCen(player, {_edytowany})
            if click action is right mouse button with shift:
                set {Hshop::items::%{_item}%::sell} to 0
                send "&7Zresetowałeś cenę sprzedaży dla&8: &a%{_item}%"
                OpenEdytorCen(player, {_edytowany})
                    
function OpenEdytorCen(p: player, typ: text):
    open chest with 4 rows named "&8%{_typ}% - Edytor Cen" to {_p}
    set slot (integers between 28 and 36) of {_p}'s current inventory to Barrier named "&cBrak slotu!"
    set slot 31 of {_p}'s current inventory to redstone block named "&aJak obsługiwać Edytor Cen?" with lore "%nl%&8[&c●&8] &7Lewy - Ustaw cenę kupna%nl%&8[&c●&8] &7Prawy - Ustaw cenę sprzedaży%nl%&8[&c●&8] &7Shift + Lewy - Reset ceny kupna%nl%&8[&c●&8] &7Shift + Prawy - Reset ceny sprzedaży"
    loop {Hshop::shops::%{_typ}%::*}:
        set slot (loop-index parsed as integer - 1) of {_p}'s current inventory to loop-value with lore "%nl%&7Cena kupna&8: &a%{Hshop::items::%loop-value%::buy}%%nl%&7Cena sprzedaży&8: &a%{Hshop::items::%loop-value%::sell}%"

function OpenEdytorItemsZcen(p: player, typ: text):
    open chest with 4 rows named "&8%{_typ}% - Items Edytor" to {_p}
    set slot (integers between 28 and 36) of {_p}'s current inventory to Barrier named "&cBrak slotu!"
    set slot 31 of {_p}'s current inventory to redstone block named "&aJak obsługiwać Edytor itemów?" with lore "%nl%&8[&c●&8] &7Kliknij na item w swoim EQ aby dodać go do sklepu%nl%&8[&c●&8] &7Kliknij środkowym przyciskiem na item w GUI aby go usunąć"
    loop {Hshop::shops::%{_typ}%::*}:
        set slot (loop-index parsed as integer - 1) of {_p}'s current inventory to loop-value
    
function ReloadEditor(p: player, type: text, Edytor: text):
    clear {_p}'s current inventory
    set {_} to 0
    if {_Edytor} is "Items":
        loop {Hshop::editor::shop::%{_type}%::*}:
            set slot {_} of {_p}'s current inventory to loop-value
            add 1 to {_}
        set slot (integers between 28 and 36) of {_p}'s current inventory to Barrier named "&cBrak slotu!"
        set slot 31 of {_p}'s current inventory to redstone block named "&aJak obsługiwać Edytor itemów?" with lore "%nl%&8[&c●&8] &7Kliknij na item w swoim EQ aby dodać go do sklepu%nl%&8[&c●&8] &7Kliknij środkowym przyciskiem na item w GUI aby go usunąć"
        stop
    if {_Edytor} is "Cen":
        loop {Hshop::editor::shop::%{_type}%::*}:
            set slot {_} of {_p}'s current inventory to loop-value with lore "%nl%&7Cena kupna&8: &a%{Hshop::items::%loop-value%::buy}%%nl%&7Cena sprzedaży&8: &a%{Hshop::items::%loop-value%::sell}%"
            add 1 to {_}
        set slot (integers between 28 and 36) of {_p}'s current inventory to Barrier named "&cBrak slotu!"
        set slot 31 of {_p}'s current inventory to redstone block named "&aJak obsługiwać Edytor Cen?" with lore "%nl%&8[&c●&8] &7Lewy - Ustaw cenę kupna%nl%&8[&c●&8] &7Prawy - Ustaw cenę sprzedaży%nl%&8[&c●&8] &7Shift + Lewy - Reset ceny kupna%nl%&8[&c●&8] &7Shift + Prawy - Reset ceny sprzedaży"
        stop
        
on inventory close:
    if uncolored name of event-inventory contains " - Items Edytor":
        set {_edytowany} to uncolored name of event-inventory
        replace all " - Items Edytor" with "" in {_edytowany}
        
        delete {Hshop::shops::%{_edytowany}%::*}
        loop all items in player's current inventory:
            if loop-value is not barrier named "&cBrak slotu!":
                if loop-value is not redstone block named "&aJak obsługiwać Edytor itemów?":
                    add type of loop-value to {Hshop::shops::%{_edytowany}%::*}
        send "&7Zapisano konfigurację!"

command /{@editor-command} [<text>] [<text>] [<text>]:
    permission: {@editor-command-permission}
    permission message: {@editor-command-noperm-msg}
    aliases: {@editor-command-aliases}
    trigger:
        {Hshop::disabled} is not set
        if arg-1 is "{@editor-arg-create}":
            if arg-2 is set:
                if {Hshop::shops::*} contains arg-2:
                    send "&cTaki sklep już istnieje!"
                    stop
                add arg-2 to {Hshop::shops::*}
                send "&aPoprawnie stworzono sklep z nazwą&8: &7%arg-2%"
                stop
            send "&cWpisz jakąkolwiek nazwę!"
            stop
        if arg-1 is "{@editor-arg-edit}":
            if arg-2 is "{@editor-arg-edit-items}":
                if arg-3 is set:
                    if {Hshop::shops::*} does not contain arg-3:
                        send "&cTaki sklep nie istnieje!"
                        stop
                    open chest with 4 rows named "&8%arg-3% - Items Edytor" to player
                    set slot (integers between 28 and 36) of player's current inventory to Barrier named "&cBrak slotu!"
                    set slot 31 of player's current inventory to redstone block named "&aJak obsługiwać Edytor itemów?" with lore "%nl%&8[&c●&8] &7Kliknij na item w swoim EQ aby dodać go do sklepu%nl%&8[&c●&8] &7Kliknij środkowym przyciskiem na item w GUI aby go usunąć"
                    loop {Hshop::shops::%arg-3%::*}:
                        set slot (loop-index parsed as integer - 1) of player's current inventory to loop-value
                    stop
                send "&cWpisz nazwę sklepu który chcesz edytować!"
                stop
            if arg-2 is "{@editor-arg-edit-price}":
                if arg-3 is set:
                    if {Hshop::shops::*} does not contain arg-3:
                        send "&cTaki sklep nie istnieje!"
                        stop
                    open chest with 4 rows named "&8%arg-3% - Edytor Cen" to player
                    set slot (integers between 28 and 36) of player's current inventory to Barrier named "&cBrak slotu!"
                    set slot 31 of player's current inventory to redstone block named "&aJak obsługiwać Edytor Cen?" with lore "%nl%&8[&c●&8] &7Lewy - Ustaw cenę kupna%nl%&8[&c●&8] &7Prawy - Ustaw cenę sprzedaży%nl%&8[&c●&8] &7Shift + Lewy - Reset ceny kupna%nl%&8[&c●&8] &7Shift + Prawy - Reset ceny sprzedaży"
                    loop {Hshop::shops::%arg-3%::*}:
                        set slot (loop-index parsed as integer - 1) of player's current inventory to loop-value with lore "%nl%&7Cena kupna&8: &a%{Hshop::items::%loop-value%::buy}%%nl%&7Cena sprzedaży&8: &a%{Hshop::items::%loop-value%::sell}%"
                    stop
                send "&cWpisz nazwę sklepu który chcesz edytować!"
                stop
        if arg-1 is "{@editor-arg-remove}":
            if arg-2 is set:
                if {Hshop::shops::*} contains arg-2:    
                    remove arg-2 from {Hshop::shops::*}
                    send "&aPoprawnie usunięto sklep z nazwą&8: &7%arg-2%"
                    stop
                send "&cTaki sklep nie istnieje!"
                stop
            send "&cWpisz nazwę!"
            stop
        if arg-1 is "{@editor-arg-list}":
            if size of {Hshop::shops::*} = 0:
                send "&cNie ma sklepów!"
                stop
            send "&eSklepy&8: "
            loop {Hshop::shops::*}:
                send " &8●&7 %loop-value%"
            stop
        else:
            send ""
            send "&e{@editor-command} - lista komend&8: "
            send " &8● &7/{@editor-command} {@editor-arg-create} <nazwa>"
            send " &8● &7/{@editor-command} {@editor-arg-edit} [{@editor-arg-edit-items}|{@editor-arg-edit-price}] <sklep>"
            send " &8● &7/{@editor-command} {@editor-arg-remove} <sklep>"
            send " &8● &7/{@editor-command} {@editor-arg-list}"
            send " &8● &7/{@shop-command} <sklep>"
            send ""

on tab complete of "/{@editor-command}":
    set tab completions for position 1 to "{@editor-arg-create}", "{@editor-arg-edit}", "{@editor-arg-remove}" and "{@editor-arg-list}"
    if tab arg-1 = "{@editor-arg-create}":
        set tab completions for position 2 to "<nazwa>"
    else if tab arg-1 = "{@editor-arg-edit}":
        set tab completions for position 2 to "{@editor-arg-edit-items}" and "{@editor-arg-edit-price}"
        if tab arg-2 = "{@editor-arg-edit-items}":
            set tab completions for position 3 to {Hshop::shops::*}
        if tab arg-2 = "{@editor-arg-edit-price}":
            set tab completions for position 3 to {Hshop::shops::*}
    else if tab arg-1 = "{@editor-arg-remove}":
        set tab completions for position 2 to {Hshop::shops::*}
        
on tab complete of "/{@shop-command}":
    set tab completions for position 1 to {Hshop::shops::*}
    
function SkWarnMSG(tekst: text):
    send formatted "%{_tekst}%" to all ops
    send "%{_tekst}%" to console

on script load:
    delete {Hshop::disabled}
    if "{@version}" is not text from "https://code.skript.pl/kZHpGETR/raw":
        SkWarnMSG("&7[&6Skript&7] &rSkrypt &6%script%.sk&r ma dostępną nową wersje! &8(&rAktualna: &6{@version}&r, nowa: &6%text from "https://code.skript.pl/kZHpGETR/raw"%&8)")
        SkWarnMSG("&7Link&8: &6https://code.skript.pl/iwokcCR0 <url:https://code.skript.pl/iwokcCR0>&8(&7Kliknij aby pobrać&8)")
    else:
        SkWarnMSG("&7[&6Skript&7] &rSkrypt &6%script%.sk&r jest aktualny!")
    if plugins "SkQuery" or "Skacket" or "SkBee" or "Vault" or "Protocollib" is not enabled:
        SkWarnMSG("&7[&6Skript&7] &cSkrypt &6%script%.sk&c został wyłączony i nie będzie działać przez brakujące pluginy!")
        SkWarnMSG("         &7Brakujące pluginy:")
        if plugin "SkQuery" is not enabled:
            SkWarnMSG("         &8● &rSkQuery <url:https://www.spigotmc.org/resources/skquery-1-13-1-18.36631/>&8(&7Kliknij aby pobrać&8)")
        if plugin "Skacket" is not enabled:
            SkWarnMSG("         &8● &rSkacket <url:https://forums.skunity.com/resources/skacket.1021/>&8(&7Kliknij aby pobrać&8)")
        if plugin "SkBee" is not enabled:
            SkWarnMSG("         &8● &rSkBee <url:https://www.spigotmc.org/resources/skbee-skript-addon.75839/>&8(&7Kliknij aby pobrać&8)")
        if plugin "Vault" is not enabled:
            SkWarnMSG("         &8● &rVault <url:https://www.spigotmc.org/resources/vault.34315/>&8(&7Kliknij aby pobrać&8)")
        if plugin "Protocollib" is not enabled:
            SkWarnMSG("         &8● &rProtocollib <url:https://www.spigotmc.org/resources/protocollib.1997/>&8(&7Kliknij aby pobrać&8)")
        set {Hshop::disabled} to true
        stop