#Wymagane dodatki: skUtilities, TuSKe, SkQuery

on load:
    if dir "plugins/Staty" doesn't exist:
        create dir "plugins/Staty"
    
on join:
    set {_f} to "plugins/Staty/%player%.yml"
    if file {_f} doesn't exist:
        create file {_f}
        set yaml value "stone" from file {_f} to 0
        set yaml value "drewno" from file {_f} to 0
        set yaml value "zgony" from file {_f} to 0
        set yaml value "rudy" from file {_f} to 0
    set {stone.%player%} to yaml value "stone" from file {_f}
    set {drewno.%player%} to yaml value "drewno" from file {_f}
    set {zgony.%player%} to yaml value "zgony" from file {_f}
    set {rudy.%player%} to yaml value "rudy" from file {_f}
    
on quit:
    set {_f} to "plugins/Staty/%player%.yml"
    set yaml value "stone" from file {_f} to {stone.%player%}
    set yaml value "drewno" from file {_f} to {drewno.%player%}
    set yaml value "zgony" from file {_f} to {zgony.%player%}
    set yaml value "rudy" from file {_f} to {rudy.%player%}
    
on mine:
    if event-block is stone:
        add 1 to {stone.%player%}
    if event-block is coal ore or iron ore or redstone ore or gold ore or diamond ore or emerald ore or quartz ore:
        add 1 to {rudy.%player%}
        
on break of log:
    add 1 to {drewno.%player%}
    
on death:
    if victim is player:
        add 1 to {zgony.%victim%}
        
command /staty [<text>]:
    aliases: statystyki, stats
    trigger:
        open virtual chest with 3 rows named "  &8» &6Statystyki" to player
        set {_x} to 0
        loop 10 times:
            format gui slot {_x} of player with 1 of black stained glass pane named "&8"
            add 1 to {_x}
        format gui slot 10 of player with 1 of diamond pickaxe named " &7» &aWykopany stone: &6%{stone.%player%}%"
        format gui slot 11 of player with 1 of black stained glass pane named "&8"
        format gui slot 12 of player with 1 of diamond axe named " &7» &aSciete drewno: &6%{drewno.%player%}%"
        format gui slot 13 of player with 1 of black stained glass pane named "&8"
        format gui slot 14 of player with 1 of red dye named " &7» &aZgony: &6%{zgony.%player%}%"
        format gui slot 15 of player with 1 of black stained glass pane named "&8"
        format gui slot 16 of player with 1 of diamond ore named " &7» &aWykopane rudy: &6%{rudy.%player%}%"
        set {_x} to 17
        loop 10 times:
            format gui slot {_x} of player with 1 of black stained glass pane named "&8"
            add 1 to {_x}