#-###############################-#
#                                 #
#            Exchange             #
#                                 #
#-###############################-#

on load:
    set {exchange::materials::*} to iron ingot, gold ingot, diamond, emerald, iron block, gold block, diamond block, emerald block
    set {exchange::materials-amount::*} to 9, 9, 9, 9, 4, 2, 1, 1

    set {exchange::results::*} to iron block, gold block, diamond block, emerald block, sunflower named "<yellow>Moneta", sunflower named "<yellow>Moneta", sunflower named "<yellow>Moneta", sunflower named "<yellow>Moneta"
    set {exchange::results-amount::*} to 1, 1, 1, 1, 1, 1, 1, 2

command /wymień [<text>]:
    cooldown: 1 minute
    cooldown message: <red>Możesz używać tą komendę co minutę 
    trigger:
        exchangeMaterials(player)

function exchangeMaterials(p: player):
    loop {exchange::materials::*}:
        continue if {_p} doesn't have loop-value
        set {_i} to rounded down (amount of loop-value in {_p}'s inventory / {exchange::materials-amount::%loop-index%})
        continue if {_i} = 0
        remove ({exchange::materials-amount::%loop-index%} * {_i}) of loop-value from {_p}'s inventory
        add ({exchange::results-amount::%loop-index%} * {_i}) of {exchange::results::%loop-index%} to {_p}'s inventory