code.skript.pl - kod wevROD0Z

#Skrypt by ChlebekPlayer
options:
    TAG: &9&lAntyLogout
    czas: 15
on quit:
    if {al::%player%} is set:
        kill player
        broadcast "{@TAG}: &cGracz %player% wyszedl z serwera podczas walki!"
on damage:
    if victim is a player:
        if attacker is a player:
            if {al::%victim%} is not set:
                send "{@TAG}: &cJestes podczas walki! Nie wychodz z serwera!" to victim
            if {al::%attacker%} is not set:
                send "{@TAG}: &cJestes podczas walki! Nie wychodz z serwera!" to attacker
            set {al::%victim%} to {@czas}
            set {al::%attacker%} to {@czas}
every 1 second:
    loop all players:
        if {al::%loop-player%} is set:
            if {al::%loop-player%} is more than 0:
                remove 1 from {al::%loop-player%}
                send action bar "{@TAG}: &cNie mozesz wylogowac sie jeszcze przez: %{al::%loop-player%}%sek" to loop-player
            else:
                clear {al::%loop-player%}
                send "{@TAG}: &aSkonczyles walke, mozesz sie wylogowac" to loop-player
on death:
    clear {al::%victim%}
on command:
    if {al::%player%} is set:
        if command is "spawn" or "home" or "tpa" or "tp" or "ec" or "enderchest" :
            cancel event
            send "{@TAG}: &cNie mozesz uzyc tej komendy podczas walki!"
on rightclick on ender chest:
    if {al::%player%} is set:
        cancel event
        send "{@TAG}: &cNie mozesz otworzyc enderchesta w trakcie walki"
on rightclick holding ender pearl:
    if {al::%player%} is set:
        cancel event